嵌套 if 查询在补丁上下文 NetLogo

Question

我想在这些条件下将补丁的颜色更改为绿色：

-如果同一列上有任意两个蓝色块并且它们的距离小于25 AND

-如果同一列上以及这些选定的蓝色补丁之间有任何黄色补丁

-然后将满足这些条件的所有补丁的颜色更改为绿色。

我正在努力在 NetLogo 中实现它，尝试使用嵌套循环但找不到方法。感谢您的任何帮助。我添加了一个我想要实现的示例图像并标记了示例蓝色补丁。

另外，显示我想在代码中做什么（对不起代码）：

     if any? patches with [pcolor = blue and
      (if any? patches with [pcolor = blue and pycor = ?(selected_first_blue's_pycor)
        if any? patches with [pcolor = yellow and pycor < ??(selected_first_blue's_pycor) and pycor > ?(selected_second_blue's_pycor)))
    [ask patches [set pcolor green]]

Answer 1

按照您的处理方式，您需要相当复杂的语句，例如：

let upper-blues patches with [color = blue and
   any? other patches with [color = blue and pxcor = [pxcor] of myself
        and pycor < [pycor] of myself and pycor > [pycor] of myself - 25]

我相信，从您希望可能变为绿色的补丁的角度来看，这会更容易。如果我正确解释了您的条件，则该补丁需要在上方/下方/处计算出最接近的黄色补丁，然后检查是否有两个蓝色补丁将黄色和自身包围起来，并且蓝色补丁彼此足够接近。我假设你已经关闭了换行。

这是一个完整的模型，它放入了一只红色海龟，而不是把补丁变成绿色，这样你就可以看到它是否正在识别正确的补丁。

to setup
  clear-all
  ask patches [set pcolor white]
  ask n-of 100 patches [set pcolor blue]
  ask n-of 100 patches [set pcolor yellow]
end

to convert-to-green
  let turn-green nobody
  ask patches
  [ let my-column patches with [pxcor = [pxcor] of myself]
    let above-yellow min-one-of my-column with [pcolor = yellow and pycor >= [pycor] of myself][pycor]
    let above-blue ifelse-value (above-yellow != nobody) [min-one-of my-column with [pcolor = blue and pycor > [pycor] of above-yellow][pycor]][nobody]
    let below-yellow max-one-of my-column with [pcolor = yellow and pycor <= [pycor] of myself][pycor]
    let below-blue ifelse-value (below-yellow != nobody) [max-one-of my-column with [pcolor = blue and pycor < [pycor] of below-yellow][pycor]][nobody]
    if above-blue != nobody and below-blue != nobody and ([pycor] of above-blue - [pycor] of below-blue < 25)
    [ set turn-green (patch-set self turn-green)
    ]
  ]
  ask turn-green [sprout 1 [set color red]]
end

如果您对它正常工作感到满意，请将ask turn-green [sprout 1 [set color red]] 更改为ask turn-green [set pcolor green]。

此代码以随机顺序检查每个补丁，如果满足条件，则将其添加到补丁集（称为变绿）中。一旦所有的补丁都被测试过，一组选定的补丁就会改变它们的颜色。这避免了黄色或蓝色补丁变为绿色并且无法供以后的补丁检查的问题。