阻塞和非阻塞分配 Verilog答案

【问题标题】：Blocking and Non-Blocking Assignments Verilog阻塞和非阻塞分配 Verilog
【发布时间】：2014-07-25 03:22:08
【问题描述】：

我在 always 块中有以下带有阻塞（代码 1）和非阻塞（代码 2）分配的代码。

但是两种情况下的输出是不同的。为什么？

我知道事件队列，但可能我无法理解“always @ (clk)”语句将放置在事件队列中的哪个位置。

// Code 1
module osc2 (clk, d);
    output clk;
    reg clk;
    input d;
    initial 
        begin
            #10 clk = 0;
            $monitor ("%d %b", $time, clk);
        end
    initial #100 $finish;       
    always @ (clk) #10 clk = ~clk;
endmodule

// Output of Code 1
10 0
20 1

// Code 2
module osc2 (clk, d);
    output clk;
    reg clk;
    input d;
    initial 
        begin
            #10 clk = 0;
            $monitor ("%d %b", $time, clk);
        end
    initial #100 $finish;       
    always @ (clk) #10 clk <= ~clk; 
endmodule

// Output of Code 2
10 0
20 1
30 0 (goes on upto 90)
90 0

【问题讨论】：

这是几天前被问到的同一个问题。格雷格很好地回答了这个问题。 stackoverflow.com/a/24918187/922723
感谢 russell，我读过，但仍有一些困惑。什么时候将安排确切的事件，在 ~clk 上或当 clk= 执行时？？？？ &总是@事件放在哪个事件队列中？？？
@KaranShah，除clk <= 和$monitor 之外的所有内容都在活动区域中。 always 块中的所有内容都是程序性的。 <= 推迟更新，但 ~clk 在返回 @ 之前被评估。如果您对调度程序的工作原理感兴趣，可以查看stackoverflow.com/a/22825856/1959732、stackoverflow.com/a/21316975/1959732，还有很多其他在线资源。
@Greg，非常感谢您提供这两个线程。它增强了我对事件队列和调度的概念，但我请求你是否能给我 code1 的 while 循环迭代（事件队列语句），那么它将对我的全面理解有很大帮助。

标签： verilog

【解决方案1】：

出于解释的目的，我解开了前两个循环的内容并展开了分解组件。下面的代码将模拟。

always @ (clk) #10 clk = ~clk;

initial while (1) // to see the loop, functionally equivalent to 'always' 
  begin           // procedural block
    begin : loop0_unraveled
      @(clk);       // suspend continuation of loop until change in clk
      #10;          // suspend continuation of loop 10 time units
      clk = ~clk;   /* eval '~clk' now
                     * update clk now
                     */
    end
    begin : loop1_unraveled
      begin // this block is functionally equivalent to '@(clk)'
        reg smpl_clk;      // local variable
        smpl_clk = clk;    // sample 
        $display("%t::Pre-Suspend  : smpl_clk=%b clk=%b", $time, smpl_clk, clk);
        wait(clk != smpl_clk); // suspend continuation of loop until
             /*  1. no other blocking statements can execute, go to next region
              *  2. All other regions are empty
              *  3. Remaining events are block
              *  4. Nothing left to do, exit simulation
              */
        $display("%t::Post-Suspend : smpl_clk=%b clk=%b", $time, smpl_clk, clk);
      end
      #10;           // unreachable
      clk = ~clk;
    end
end

always @ (clk) #10 clk <= ~clk;

initial while (1) // to see the loop, functionally equivalent to 'always' 
  begin           // procedural block
    begin : loop0_unraveled       
      @(clk);       // suspend continuation of loop until change in clk
      #10;          // suspend continuation of loop 10 time units
      clk <= ~clk;  /* eval '~clk' now,
                     * update clk after all blocking statements are suspended
                     */
    end
    begin : loop1_unraveled
      begin         // this block is functionally equivalent to '@(clk)'
        reg smpl_clk;      // local variable
        smpl_clk = clk;    // sample 
        $display("%t::Pre-Suspend  : smpl_clk=%b clk=%b",$time, smpl_clk, clk);
        wait(clk != smpl_clk); // suspend continuation of loop until true
             /*  1. no other blocking statements can execute, go to next region
              *  2. In NBA region update clk
              *  3. Go back to active region
              *  4. Eval true, continue
              */
        $display("%t::Post-Suspend : smpl_clk=%b clk=%b", $time, smpl_clk, clk);
      end
      #10;           // reached
      clk <= ~clk;
    end
end                  // Go to top of the loop

正如我已经提到的here，自触发块在实践中并不常见。时钟发生器通常植入类似于：

initial begin
  #10 clk = 0;
  forever #10 clk = ~clk;
end

或者

always #10 clk = (clk===1'b0);

【讨论】：