为一个 id 生成变量观察值以观察另一个 id 的新变量

Question

我有一个允许链接朋友（即观察同伴组）的数据集，从而可以观察个人朋友的特征。我拥有的是一个 8 位标识符，id，每个 id 的朋友 id（最多 10 个朋友），然后是许多特征变量。

我想取一个人并创建一个变量，它是每个朋友的外国出生状态。

我已经为每个人设置了一个指标，如果在外国出生，则为 1。下面是一个小例子，仅供一位朋友使用。注意，MF1 表示男性朋友 1，然后MF1id 是男性朋友 1 的 id 号。受访者最多可以列出 5 个男性朋友和 5 个女性朋友。

所以，我需要Stata查看MF1id，然后将其匹配到id列，然后查看f_born匹配的id，最后输入f_born的值回到原来的id下MF1f_born.

edit：我在解释数据结构方面做得很差。我有一个横截面，因此每个唯一 ID 进行 1 次观察。第 1 行是前 8 位 id 编号，所有变量都在该行之后。重复的 id 编号介于为每个人列出的朋友 id（例如 mf1id）和 id 列之间。我希望这更清楚一点。

Answer 1

Kevin Crow 写了 vlookup，让这种事情变得很容易：

use http://www.ats.ucla.edu/stat/stata/faq/dyads, clear
drop team y
rename (rater ratee) (id mf1_id)
bys id: gen f_born = mod(id,2)==1

net install vlookup
vlookup mf1_id, gen(mf1f_born) key(id) value(f_born)

Answer 2

所以，Dimitriy 对 vlookup 的建议是完美的，但它对我不起作用。在使用我的数据集、Dimitriy 用于他的示例的 UCLA 数据以及我创建的玩具数据集尝试 vlookup 之后，vlookup 在程序尝试将临时文件保存到我的临时文件夹时总是失败。下面是vlookup的程序。注意它设置 tempfile 文件，操作数据，然后保存文件。

*! version 1.0.0 KHC 16oct2003
program define vlookup, sortpreserve
	version 8.0
	syntax varname, Generate(name) Key(varname) Value(varname)
	qui {
		tempvar g k
		egen `k' = group(`key')
		egen `g' = group(`key' `value')
		local k = `k'[_N]
		local g = `g'[_N]
		if `k' != `g' {
			di in red "`value' is unique within `key';"
			di in red /*
			*/ "there are multiple observations with different `value'" /*
			*/ " within `key'."
			exit 9
		}
		preserve
			tempvar g _merge
			tempfile file
			sort `key'
			by `key' : keep if _n == 1
			keep `key' `value'
			sort `key'
			rename `key'  `varlist'
			rename  `value' `generate'
			save `file', replace
		restore
		sort `varlist'
		joinby `varlist' using `file', unmatched(master) _merge(`_merge')
		drop `_merge'

	}
end
exit

由于某种原因，Stata 在保存“文件”替换点处给了我一个错误“无效文件”。我有一个受限制的数据集，要求将我的所有 Stata 临时文件指向一个非常特定的文件夹，该文件夹有一个经常扫描它的擦除程序。我不知道为什么这会造成问题，但也许确实如此，我真的不知道。无论如何，我调整了 vlookup 程序，它似乎可以满足我现在的需求。

clear all
set more off
capture log close


input aid mf1aid fborn
	  1	  2	     1
	  2   1		 1
	  3   5      0
	  4	  2      0
	  5   1      0
	  6   4      0
	  7   6      1
	  8   2      .
	  9   1      0
	  10  8      1
end		


program define justlinkit, sortpreserve
	syntax varname, Generate(name) Key(varname) Value(name)
	qui {
preserve 
	tempvar g _merge
	sort `key'
	by `key' : keep if _n ==1
	keep `key' `value'
	sort `key'
	rename `key' `varlist'
	rename `value' `generate'
	save "Z:\Jonathan\created data sets\justlinkit program\fchara.dta",replace
restore
sort `varlist'
joinby `varlist' using "Z:\Jonathan\created data sets\justlinkit program\fchara.dta", unmatched(master) _merge(`_merge')
drop `_merge'

	}
end

// set trace on
justlinkit mf1aid, gen(mf1_fborn) key(aid) value(fborn)

sort aid 
list

嗯，这解决了我的问题。感谢所有回复的人，如果没有你，我不会想到这一点。