如何在 Stata 中创建日期序列？

Question

我希望在 Stata 中创建一个日期序列。在这个论坛和其他论坛上搜索并没有为 Stata 提供任何有用的代码。 R 有很多答案，例如this 链接上所示。我想创建一个从 2000 年 1 月 1 日到 2010 年 12 月 31 日的序列。我该怎么做？

Answer 1

日期在任何软件中都可能很棘手。在 Stata 中，与任何其他软件一样，仔细阅读文档确实无可替代。 help dates and times 回答了大多数问题。一个可能会让粗心大意的怪癖是，Stata 中的date() 是一个用于创建daily 日期变量的函数，而没有其他类型。从 Stata 13 开始，新用户在寻找每日日期时最好使用同义函数 daily()。 也就是说，另一个函数在这里更方便地创建日期序列，mdy()。

这是一个例子：

clear 
di mdy(1,1,2000)
di mdy(12,31,2010)
di mdy(12,31,2010) - mdy(1,1,2000)
set obs 4018
gen mydate = mdy(12,31,1999) + _n
format mydate %td
list in 1
list in L 

注意事项：

1. mdy() 根据表示月、日和年的参数创建每日日期变量。

2. _n 是观察号，向上 1。

3. 因此，您需要计算出开始日期和所需的观察次数，然后只需将所需的常量添加到_n。

4. Stata 适用于 1960 年 1 月 1 日的每日日期，但此解决方案并不取决于您是否知道这一点。

附：在现已删除的答案中，@Caty 似乎要求提供一系列每月日期。这是一个经过编辑的版本：

当我尝试这样做时，我的日期看起来像这样 01jan2000、02jan2000。但 它们应该是每月：01jan2000、01feb2000。

如果您有月度数据，那么至少就 Stata 而言，使用每月第一天的每日日期是完全没有必要的，也没有任何优势。事实上，通过创建这样一个序列，您可以创建一个间隔为 27、28、29 和 30 天的序列，因此即使是规则间隔的序列也不行。这些差距将使Stata中的许多分析变得尴尬，有些甚至不可能。类似的 cmets 适用于宿舍。 （如果你有几个星期，每天相隔 7 天是最好的框架，这是另一回事。）

clear 
di ym(2000, 1)
di ym(2010, 12)
di ym(2010, 1) - ym(2000,1)
set obs 121 
gen mydate = ym(1999, 12) + _n
format mydate %tm 
l in 1
l in L 

注意事项：

1. ym() 从表示年份和月份的参数创建每月日期变量。

2. _n 是观察号，向上 1。

3. 因此，您需要计算出开始日期和所需的观察次数，然后只需将所需的常量添加到_n。

4. Stata 适用于 1960 年 1 月的每月日期，但此解决方案并不取决于您是否知道这一点。

编辑月末每日序列很容易使用一个技巧，您可能会因为没有立即看到而自责。假设我们想要 2015 年 1 月到 2016 年 12 月的月底。那么每个月的月底就在下月初的前一天。无需担心不同长度的月份或闰年。 Stata 知道日历的详细信息，因此您不必告诉它它们是什么。

. clear

. set obs 24 
number of observations (_N) was 0, now 24

. gen mdate = ym(2015, 1) + _n 

. gen ddate = dofm(mdate) - 1 

. format %td ddate

. format %tm mdate 

. list 

     +---------------------+
     |   mdate       ddate |
     |---------------------|
  1. |  2015m2   31jan2015 |
  2. |  2015m3   28feb2015 |
  3. |  2015m4   31mar2015 |
  4. |  2015m5   30apr2015 |
  5. |  2015m6   31may2015 |
     |---------------------|
  6. |  2015m7   30jun2015 |
  7. |  2015m8   31jul2015 |
  8. |  2015m9   31aug2015 |
  9. | 2015m10   30sep2015 |
 10. | 2015m11   31oct2015 |
     |---------------------|
 11. | 2015m12   30nov2015 |
 12. |  2016m1   31dec2015 |
 13. |  2016m2   31jan2016 |
 14. |  2016m3   29feb2016 |
 15. |  2016m4   31mar2016 |
     |---------------------|
 16. |  2016m5   30apr2016 |
 17. |  2016m6   31may2016 |
 18. |  2016m7   30jun2016 |
 19. |  2016m8   31jul2016 |
 20. |  2016m9   31aug2016 |
     |---------------------|
 21. | 2016m10   30sep2016 |
 22. | 2016m11   31oct2016 |
 23. | 2016m12   30nov2016 |
 24. |  2017m1   31dec2016 |
     +---------------------+

Answer 2

Stata 将日期处理为具有相应格式的整数，因此归结为找出您需要的整数、生成序列并给出适当的格式。一种方法是：

clear all
set more off

// get corresponding integers
local start = date("2000/01/01", "YMD")
local end = date("2010/12/31", "YMD")
local ob = `end' - `start' + 1

// generate variable
set obs `ob'
egen date = seq(), from(`start') to(`end')
format %td date

list

请参阅 help datetime 和 [U] 24 Working with dates and times。