即使找不到变量，也使Stata命令“drop”继续

Question

我有一组 18 个 Stata 数据文件（每年一个），它们的名称是：

{aindresp.dta, bindresp.dta, ... , rindresp.dta}

我想从每个数据集中消除一些变量。为此，我想利用数据集中的许多变量具有相同名称的事实，加上数据集前缀 (a, b, c, ... r) 给出的前缀。例如，变量rach12 在数据集aindresp.dta 中被称为arach12 等。因此，为了清理每个数据集，我运行如下循环：

clear all
local list a b c d e f g h i j k l m n o p q r
foreach var of local list {
use `var'indresp.dta
drop `var'rach12 `var'jbchc1 `var'jbchc2 `var'jbchc3 `var'xpchcf var'xpchc
save `var'indresp.dta, replace
}

实际的循环要大得多。我正在删除大约 200 个变量。

问题是一些变量会随着时间的推移而改变名称，或者在几年后消失。添加其他变量。因此，一旦找不到变量，循环就会停止。这是因为 Stata 中的drop 命令停止了。然而，该命令无法强制它继续执行。

我怎样才能实现我的目标？我不想手动检查每个数据集。

Answer 1

help capture

您可以将capture 放在drop 前面。您可以继续前进，但更好的做法是标记哪些数据集失败。

在这个示例代码中，我假设如果你没有 drop 任何东西，save, replace 就没有意义。基本思想是命令失败会导致在_rc 中可访问的非零错误代码。如果发生故障，这将是肯定的（真），否则为零（假）。

更复杂的过程是循环相关变量并标记未找到的特定变量。

clear all
local list a b c d e f g h i j k l m n o p q r
foreach var of local list {
    use `var'indresp.dta
    capture drop `var'rach12 `var'jbchc1 `var'jbchc2 `var'jbchc3 `var'xpchcf var'xpchc
    if _rc { 
        noisily di "Note: failure for `var'indresp.data" 
    } 
    else save `var'indresp.dta, replace
}

另见Does Stata have any `try and catch` mechanism similar to Java?

编辑：

如果您想drop 任何存在，那么这应该足以解决您的问题。

clear all
local list a b c d e f g h i j k l m n o p q r
foreach var of local list {

    use `var'indresp.dta
    capture drop `var'rach12 `var'jbchc1 `var'jbchc2 `var'jbchc3 `var'xpchcf var'xpchc
    if _rc { 
        di "Note: problem for `var'indresp.data" 
        checkdrop `var'rach12 `var'jbchc1 `var'jbchc2 `var'jbchc3   
    } 

    save `var'indresp.dta, replace
}

checkdrop 类似于

*! 1.0.0 NJC 1 April 2016 
program checkdrop
    version 8.2 

    foreach v of local 0 { 
        capture confirm var `v' 
        if _rc == 0 { 
            local droplist `droplist' `v'  
        } 
        else local badlist `badlist' `v'  
    } 

    if "`badlist'" != "" {
        di _n "{p}{txt}variables not found: {res}`badlist'{p_end}" 
    } 

    if "`droplist'" != "" { 
        drop `droplist' 
    } 
end