如何将一个批处理文件中的值返回给调用者批处理文件

Question

我有一个通用的 .bat 文件，它读取 status.xml 文件并找出状态字段的值。这个批处理文件然后被其他批处理文件调用以找出状态值。调用批处理文件将文件名发送到公共 bat 文件。 我无法将公共批处理文件中的状态发送到调用批处理文件。 有人可以帮忙吗？

main batch file
-- will call the common bat file and send the file name and a variable as arguments
setlocal
call Common.bat c:\folderdir\files\status.xml val1
-- trying to print the status returned by the common bat file
echo [%val1%]

common batch file
@ECHO off
setlocal EnableDelayedExpansion

rem will loop through the file and read the value of the status tag
(for /F "delims=" %%a in (%1) do (
set "line=%%a"
set "newLine=!line:<Interface_status>=!"
set "newLine=!newLine:</Interface_status>=!"
if "!newLine!" neq "!line!" (
  @echo Status is !newLine!
rem I want to send`enter code here` the value of newLine to the calling batch file
  set %~2 = !newLine!   <--this does not work
)

)) 

Answer 1

在 SETLOCAL/ENDLOCAL 括号内（EOF=ENDLOCAL）对环境所做的任何更改都会被撤销。

您需要在Common.bat 中设置一个变量，该变量在最后的右括号之后可见（即您的返回值 - 它可能是一个空字符串。

然后，在common.bat 的最后一个右括号之后的行中，放入以下行：

ENDLOCAL&set %~2=%returnvalue%

returnvalue 包含您希望返回的 er 值（有趣的是...）

顺便说一句：字符串SET 是空间敏感的。如果该行有效，您将设置变量 "VAR1 " - 而不是 "VAR1" - = 之前的空格将包含在变量名称中 - 并且 = 之后的任何空格同样包含在值中已分配。

语法

set "var=value"

通常用于排除一行中的任何杂散尾随空格（某些编辑器可能会留下）

---

（叹气）...

@ECHO off
setlocal EnableDelayedExpansion

rem will loop through the file and read the value of the status tag
(for /F "delims=" %%a in (%1) do (
set "line=%%a"
set "newLine=!line:<Interface_status>=!"
set "newLine=!newLine:</Interface_status>=!"
if "!newLine!" neq "!line!" (
  @echo Status is !newLine!
rem SET THE RETURN VALUE
  set RETURNVALUE=!newLine!
)

)) 

ENDLOCAL&SET %~2=%RETURNVALUE%

Answer 2

Peter Wright 描述了主要技术。

最后一个问题似乎是在不丢失值的情况下退出for循环。

您可以使用GOTO :break 作为GOTO 立即停止所有循环。

不能在ENDLOCAL 块中使用!newline!，因为它会在ENDLOCAL 之后扩展，但它是空的。

@ECHO off
setlocal EnableDelayedExpansion

for /F "delims=" %%a in (%1) do (
  set "line=%%a"
  set "newLine=!line:<Interface_status>=!"
  set "newLine=!newLine:</Interface_status>=!"
  if "!newLine!" neq "!line!" (
    @echo Status is !newLine!
    goto :break
  )
)

( 
  endlocal
  set "%~2=%newLine%"
)

如果你在 newLine 中的值可能包含引号，那么最好使用一种更安全的技术：

for /F "delims=" %%a in ("!newline!") DO (
  endlocal
  set "%~2=%%~a" 
)