Excel/GSheets 为动态列表中的重复值添加唯一标志答案

【问题标题】：Excel/GSheets add unique flag to reoccuring values in a dynamic listExcel/GSheets 为动态列表中的重复值添加唯一标志
【发布时间】：2020-12-10 01:16:41
【问题描述】：

作为我之前在此处发布的问题的后续 -Excel/GSheets count unique versus reoccuring values in dynamic list，我希望计算 30k 多名网络研讨会参与者列表中的唯一值，但这次跨越多个标准。

这里的逻辑与简单的 COUNTIFS 公式有点不同，因为我需要保留所有行以在 Google Data Studio 中进行可视化和交互 - 所以换句话说，我需要一个公式来插入一个唯一标志（“New " 或 "Returning") 基于唯一性参数。

简而言之，我需要在这个公式中添加逻辑来考虑不同的唯一性：

=IF(COUNTIF($B$2:$B2,B2)>1,"Returning","New")

让我们使用这个简化的数据集示例来解释一下，注意除 P1 之外的所有与会者都是唯一的，并注意 F 和 G 列中的值应如何根据标准进行更改。请注意，我添加了边框和颜色以便于理解。

链接到示例数据 - https://drive.google.com/file/d/1LxirDbk-9w5zu5qqFNoBI9QiK4Za6lFA/view?usp=sharing

这是数据进入的图表：

任何帮助将不胜感激！谢谢！

【问题讨论】：

当您说 注意，单元格已被合并以提高可读性和更易于理解 是指实际工作表中的方法吗？如果是这样，虽然这可能更容易阅读，但它会使编写公式变得更加困难
@chrisneilsen 好点，这只是为了便于阅读，我已将示例集更新为实际组织方式
我发现在提供样本表时帮助他人更容易 - 而不仅仅是图像 - 这样我就不必重新创建样本数据来验证解决方案和工作表布局.非常感谢。
@kirkg13 这里是drive.google.com/file/d/1LxirDbk-9w5zu5qqFNoBI9QiK4Za6lFA/…
您是否正在寻找 F 和 G 列的公式，以标记新的或返回的，类似于 E 的公式？

标签： excel google-sheets excel-formula formula google-sheets-formula

【解决方案1】：

看起来有几种方法可以处理这个问题，但只是背负 E 列中已有的内容......您可以通过组合您的参加者列来扩展它以处理 F 和 G 中的多个条件分别与那些周和日列。

这将是 F2 的公式（只需像在 E 中那样将其向下拖动）

=IF(COUNTIF(arrayformula($B$2:$B2&$C$2:$C2),B2&C2)>1,"Returning","New")

这将是 G2 的公式

=IF(COUNTIF(arrayformula($B$2:$B2&$D$2:$D2),B2&D2)>1,"Returning","New")

同样，可能还有许多其他方法可以处理此问题，但其概念是使用组合的与会者和周或日指示器作为组合的唯一键来查找列表本身。

这是一张包含解决方案的表格，供您复制 https://docs.google.com/spreadsheets/d/1DGfVRKnzJM6-tmNPy5GGdD_ca8YAZy0LRB6ci4nDHK0/edit?usp=sharing

【讨论】：

绝对精彩，谢谢国王布拉沃

【解决方案2】：

作为早期答案的替代方案（我是一个慢工！）考虑这种方法，它基本上非常相似，但可以填充列。

这是 E1、F1 和 G1 中的三个公式。在 E1：

={"Attendee unique";
  ARRAYFORMULA(if(COUNTIFS(B2:B,B2:B,ROW(B2:B),"<="&ROW(B2:B))>1,"Returning","New"))}

在 F1 中：

={"Week Unique";
  ARRAYFORMULA(if(COUNTIFS(B2:B&C2:C,B2:B&C2:C,ROW(B2:B),"<="&ROW(B2:B))>1,"Returning","New"))}

在 G1 中：

={"Day Unique";
 ARRAYFORMULA(IF(COUNTIFS(B2:B&C2:C&D2:D,B2:B&C2:C&D2:D,ROW(B2:B),"<="&ROW(B2:B))>1,"Returning","New"))}

【讨论】：