两列中任意两个值之间的最大差值公式答案

【问题标题】：Formula for maximum difference between any two values in two columns两列中任意两个值之间的最大差值公式
【发布时间】：2017-03-15 22:17:50
【问题描述】：

我在 D 列和 E 列中有两组数据。它们都是日期和时间。 B 列是退出日期和时间，A 列是进入日期和时间。我想知道的是退出日期和时间与下一个进入日期和时间之间的最大差距。

关键在于它必须满足 A 列和 J 列中的某些条件——它们是文本的位置。

到目前为止，公式如下所示：

=MAX(LARGE(IF((A1:A2000=H6)*(J1:J2000=B6),(D1:D2000-E1:E2000)),ROW(INDIRECT("1:"&-1+COUNT(IF((A1:A2000=H6)*(J1:J2000=B6),(D1:D2000-E1:E2000))))))-LARGE(IF((A1:A2000=A6)*(J1:J2000=B6),(D1:D2000-E1:E2000)),ROW(INDIRECT("2:"&COUNT(IF((A1:A2000=H6)*(J1:J2000=B6),(D1:D2000-E1:E2000)))))))

列中的数据看起来像：

Col A     Col D             Col E               Col J

ABC       14/03/2017 10:17  14/03/2017 10:52    131
ABC       14/03/2017 10:17  14/03/2017 10:52    131
ABC       14/03/2017 14:15  14/03/2017 14:42    131

抱歉格式化，没弄好！ A 中还有几行数据和不同的位置。

所以理想情况下，公式将返回 14/03/2017 14:15 - 14/03/2017 10:52 = 0.1409

【问题讨论】：

这个数据是按输入时间排序的吗？
您是否将其用作数组公式 ??
回答问题 - 不，它没有任何特定的顺序。我试图使用数组公式，但 Jeeped 无需这样做就解决了问题。

标签： excel excel-formula formula

【解决方案1】：

尝试将其作为标准公式（即非 CSE），

=TEXT(INDEX(D:D, AGGREGATE(14, 6, ROW(D2:INDEX(D:D, MATCH(1E+99, D:D)))/((A2:INDEX(A:A, MATCH(1E+99, E:E))=B6)*(J2:INDEX(J:J, MATCH(1E+99, E:E))=H6)), 1)), "dd/mm/yyyy hh:mm")&" - "&
 TEXT(INDEX(E:E, AGGREGATE(15, 6, ROW(E2:INDEX(E:E, MATCH(1E+99, E:E)))/((A2:INDEX(A:A, MATCH(1E+99, E:E))=B6)*(J2:INDEX(J:J, MATCH(1E+99, E:E))=H6)), 1)), "dd/mm/yyyy hh:mm")&" = "&
 TEXT(INDEX(D:D, AGGREGATE(14, 6, ROW(D2:INDEX(D:D, MATCH(1E+99, D:D)))/((A2:INDEX(A:A, MATCH(1E+99, E:E))=B6)*(J2:INDEX(J:J, MATCH(1E+99, E:E))=H6)), 1))-
  INDEX(E:E, AGGREGATE(15, 6, ROW(E2:INDEX(E:E, MATCH(1E+99, E:E)))/((A2:INDEX(A:A, MATCH(1E+99, E:E))=B6)*(J2:INDEX(J:J, MATCH(1E+99, E:E))=H6)), 1)), "0.0000")

结果为：

14/03/2017 14:15 - 14/03/2017 10:52 = 0.1410

【讨论】：

哈！我应该更清楚，我只需要返回 0.1410 - 只是想展示我是如何到达那里的。但我认为整个事情实际上更清晰，并且显示出最长的差距。顺便说一句，这真是太棒了，完全回答了我的问题。干得好吉普车。
没有将此标记为已解决 - 现在有。再次干得好。