如何在不使用任何向导的情况下将表从 oracle 数据库导出到本地计算机

Question

我想开发一个 PL/SQL 过程，该过程将创建一个最终表格并自动将表格导出到我本地计算机的 excel/文本文件中。有没有办法做到这一点？是否有任何特定命令可以将我的最终表格导出为 excel/文本文件到我的本地计算机，而无需手动单击任何内容？

Answer 1

您可以在 Oracle 中使用 UTL_FILE 执行此操作。使用UTL_FILE，您可以很好地控制输出文件格式，您似乎在这里需要它，您可以轻松地使用dbms_job 安排此过程每天自动运行 在某个时间。

以下是来自Ask Tom的此类程序的一个工作示例

create or replace procedure dump_table_to_csv( p_tname in varchar2, p_dir   in varchar2, p_filename in varchar2 )
  is      l_output        utl_file.file_type;
       l_theCursor     integer default dbms_sql.open_cursor;
        l_columnValue   varchar2(4000);
        l_status        integer;
        l_query         varchar2(1000)
                       default 'select * from ' || p_tname;
       l_colCnt        number := 0;
       l_separator     varchar2(1);
       l_descTbl       dbms_sql.desc_tab;
   begin
       l_output := utl_file.fopen( p_dir, p_filename, 'w' );
       execute immediate 'alter session set nls_date_format=''dd-mon-yyyy hh24:mi:ss'' ';

       dbms_sql.parse(  l_theCursor,  l_query, dbms_sql.native );
       dbms_sql.describe_columns( l_theCursor, l_colCnt, l_descTbl );

       for i in 1 .. l_colCnt loop
           utl_file.put( l_output, l_separator || '"' || l_descTbl(i).col_name || '"' );
           dbms_sql.define_column( l_theCursor, i, l_columnValue, 4000 );
           l_separator := ',';
       end loop;
       utl_file.new_line( l_output );

       l_status := dbms_sql.execute(l_theCursor);

       while ( dbms_sql.fetch_rows(l_theCursor) > 0 ) loop
           l_separator := '';
           for i in 1 .. l_colCnt loop
               dbms_sql.column_value( l_theCursor, i, l_columnValue );
               utl_file.put( l_output, l_separator || l_columnValue );
               l_separator := ',';
           end loop;
           utl_file.new_line( l_output );
       end loop;
       dbms_sql.close_cursor(l_theCursor);
       utl_file.fclose( l_output );

       execute immediate 'alter session set nls_date_format=''dd-MON-yy'' ';
   exception
       when others then
           execute immediate 'alter session set nls_date_format=''dd-MON-yy'' ';
           raise;
   end;
   /

这就是您调用此工作的方式。

exec dump_table_to_csv( 'emp', '/tmp', 'tkyte.emp' );