VBA访问中的while循环

Question

我有根据用户输入构建 Table1 的删除和附加函数。因此，Table1 为每个用户附加了不同数量的记录。

我的 SQL 代码用于查找日期，但它只执行一次，我需要循环 SQL 代码以获得表的长度。我不擅长编码，我尝试了一个 while 语句，不确定我是否可以在标准中使用变量 Z，但我希望它运行直到填充了具有最小 ID 值的记录中的到期日期。

这是我尝试过的：

Private Sub Command7_Click()
Y = DMax("ID", "Table1", BuildCriteria("Due_date", dbDate, "Null"))
A = DMin("ID", "Table1", BuildCriteria("Due_date", dbDate, "Not Null"))
X = DMin("ID", "Table1")
Z = DLookup("Due_date", "Table1", BuildCriteria("ID", dbLong, CStr(X)))

B = DLookup("Duration", "Table1", BuildCriteria("ID", dbLong, CStr(Y)))
C = DLookup("Due_date", "Table1", BuildCriteria("ID", dbLong, CStr(A)))
E = DateAdd("d", -B, C)

Dim SQL As String

SQL = "UPDATE Table1 " & _
    "SET " & BuildCriteria("Due_date", dbDate, CStr(E)) & " " & _
    "WHERE " & BuildCriteria("ID", dbLong, CStr(Y))


While Z Is Null
DoCmd.RunSQL SQL

End While

End Sub

举例说明：

• 运行 SQL 之前

• 运行一次 SQL 后

• 点击几次后

目标是单击一次，整个表格就会填满

Answer 1

您的变量Z 包含DLookup 函数返回的结果，当评估为您的子Command7_Click 定义的第四行时；除非重新定义变量，否则该变量的值不会改变。

使用BuildCriteria 函数有点模糊了代码的意图，因此很难建议编写代码的最佳方式...

编辑：BuildCriteria 对我来说是新的 - 感谢@Andre 指出这一点。

由于您的 SQL 语句的内容是静态的，因此不需要循环，因为循环内没有任何变化 - SQL 语句将更新所有符合您的条件的记录，并且不会对每次后续迭代执行任何操作 (除非，也就是说，您将记录更新到的值也满足选择标准）。

---

编辑

根据您的其他解释和屏幕截图，您可以通过遍历按您的ID 字段排序的记录集并为每条记录连续计算适当的Due_date 来完成任务 - 类似于：

Private Sub Command7_Click()
    Dim dbs As DAO.Database
    Dim rst As DAO.Recordset
    Dim dat As Date
    Set dbs = CurrentDb
    Set rst = dbs.OpenRecordset("select * from Table1 order by ID desc")
    With rst
        If Not .EOF Then
            .MoveFirst
            Do Until .EOF
                If Not IsNull(!Due_date) Then
                    dat = !Due_date
                Else
                    dat = DateAdd("d", -!Duration, dat)
                    .Edit
                    !Due_date = dat
                    .Update
                End If
                .MoveNext
            Loop
        End If
        .Close
    End With
    Set rst = Nothing
    Set dbs = Nothing
End Sub

尽管根据您的屏幕截图，您似乎正在尝试像 Excel 电子表格一样使用 Access。

Answer 2

考虑实际上没有For 循环，没有BuildCriteria，甚至没有VBA SQL。将更新查询另存为在单击按钮时运行的 MS Access 操作查询对象。

具体来说，您需要几个域函数 --DLookUp、DSum 和 DMax-- 在其中计算持续天数的运行总和（即相关聚合计算），然后是 DateAdd结果到相应最大值ID 的DueDate，没有丢失DueDate。

SQL

UPDATE myTable d
SET d.DueDate =  DateAdd("d", -1 * DSum("Duration", "DueDateDuration", "ID >= " & d.ID),  
                                         DLookUp("DueDate", "DueDateDuration", "ID = " &  
                                                 DMax("ID", "DueDateDuration", "DueDate IS NOT NULL") 
                                       )
                        )
WHERE d.DueDate IS NULL;

VBA

Private Sub Command7_Click()
    DoCmd.OpenQuery "mySavedUpdateQuery"     ' WITH WARNINGS

    CurrentDb.Execute "mySavedUpdateQuery"   ' WITHOUT WARNINGS
End Sub

---

在样本数据上进行演示：

更新前 (mytable)

ID      Item       Duration     DueDate
2674    Issue             1   2/18/2019
2675    Shipping          1   2/19/2019
2678    Completed         0   2/20/2019
2679    Issue             1 
2680    Shipping         10 
2681    Other             6 
2682    Buy Off           6 
2683    Punch List        3 
2684    Completed         0   3/29/2019

更新后 (mytable)

ID      Item       Duration     DueDate
2674    Issue             1   2/18/2019
2675    Shipping          1   2/19/2019
2678    Completed         0   2/20/2019
2679    Issue             1    3/3/2019
2680    Shipping         10    3/4/2019
2681    Other             6   3/14/2019
2682    Buy Off           6   3/20/2019
2683    Punch List        3   3/26/2019
2684    Completed         0   3/29/2019