Vb.NET MS Access SQL UPDATE 语法问题

Question

我已经为此苦苦琢磨了好几个小时，但还没有做好，所以我决定发帖。

我的 Vb.NET 应用程序在硬盘上有 2 张 Jpg。一个是LowRes，另一个是HighRes。我想通过INSERT 将两张图片保存在Microsoft Access 2007 数据库中的同一记录中，这工作正常，然后UPDATE 添加第二张。 UPDATE 不起作用。

我拼凑了一堆我在网上找到的INSERT 代码（边走边学），最终找到了一些真正有效的方法。然而，尝试调整函数以执行更新以添加第二张图片被证明是困难的。我怀疑这与我指定参数错误有关？

数据库有 1 个表 Records 和 3 列 RecordID（这是文本，以及从 Form1.Tb_RecordID.Text 提取的自动编号主键）、HighRes（这是 OLE）和 LowRes（其中也是 OLE)。该数据库名为Database.accdb。

我调用子程序：

Save_To_Database("LowProfile.jpg", "LowRes")

如果我想要INSERT "LowRes" 列中的 OLE 图像。然后我打电话给

Update_To_Database("HighProfile.jpg", "HighRes")

用HighRes 图片更新记录。我最终希望一对一地整合这些函数，并使用 ByVals 来确定它是应该更新还是插入。

这很好用：

Sub Save_To_Database(ByVal Filename As String, ByVal Res As String)

    Dim cnString As String = "PROVIDER=Microsoft.ACE.OLEDB.12.0;Data Source=Database.accdb"
    Dim theQuery As String = "INSERT INTO Records([RecordID],[" & Res & "]) values (" & Form1.Tb_RecordID.Text & ", @Img)"

    Try
        Dim fs As FileStream
        fs = New FileStream(Filename, FileMode.Open, FileAccess.Read)
        Dim picByte As Byte() = New Byte(fs.Length - 1) {}
        fs.Read(picByte, 0, System.Convert.ToInt32(fs.Length))
        fs.Close()
        Dim CN As New OleDbConnection(cnString)
        CN.Open()
        Dim imgParam As New OleDbParameter()
        imgParam.OleDbType = OleDbType.Binary
        imgParam.ParameterName = "Img"
        imgParam.Value = picByte
        Dim cmd As New OleDbCommand(theQuery, CN)
        cmd.Parameters.Add(imgParam)
        cmd.ExecuteNonQuery()
        MessageBox.Show("Image successfully saved.")
        cmd.Dispose()
        CN.Close()
        CN.Dispose()
    Catch ex As Exception
        MessageBox.Show(ex.Message)
    End Try

End Sub

但是，我的UPDATE 代码失败，SQL 语句出现语法错误：

Sub Update_To_Database(ByVal Filename As String, ByVal Res As String)

    Dim cnString As String = "PROVIDER=Microsoft.ACE.OLEDB.12.0;Data Source=Database.accdb"
    Dim theQuery As String = "UPDATE Records SET ([" & Res & "]) values (@Img) WHERE RecordID =" & Form1.Tb_RecordID.Text

    MsgBox(theQuery)

    Try
        Dim fs As FileStream
        fs = New FileStream(Filename, FileMode.Open, FileAccess.Read)
        Dim picByte As Byte() = New Byte(fs.Length - 1) {}
        fs.Read(picByte, 0, System.Convert.ToInt32(fs.Length))
        fs.Close()
        Dim CN As New OleDbConnection(cnString)
        CN.Open()
        Dim imgParam As New OleDbParameter()
        imgParam.OleDbType = OleDbType.Binary
        imgParam.ParameterName = "Img"
        imgParam.Value = picByte
        Dim cmd As New OleDbCommand(theQuery, CN)
        cmd.Parameters.Add(imgParam)
        cmd.ExecuteNonQuery()
        MessageBox.Show("Image successfully saved.")
        cmd.Dispose()
        CN.Close()
        CN.Dispose()
    Catch ex As Exception
        MessageBox.Show(ex.Message)
    End Try

End Sub

有人看到问题了吗？或者改进代码的方法？

Answer 1

您最初的问题是您尝试使用插入语句的语法编写更新语句。一个简单的解决方法是将更新语句更改为正确的语法。

但是，您的代码中有很多东西可以并且应该被更改，所以我根据您的代码编写了一个仍然可以进一步改进的示例：

Sub Save_To_Database(ByVal Filename As String, ByVal RecordId As String, ByVal IsHighResolution As Boolean, ByVal IsNew As Boolean)

    Dim theQuery As String
    Dim cnString As String = "PROVIDER=Microsoft.ACE.OLEDB.12.0;Data Source=Database.accdb"

    If IsNew Then
        theQuery = "INSERT INTO Records([RecordID],[" & IIf(IsHighResolution, "HighRes", "LowRes") & "]) values (@RecordId, @Img)"
    Else
        theQuery = "UPDATE Records SET " & IIf(IsHighResolution, "HighRes", "LowRes") & " = @Img WHERE RecordID = @RecordId"
    End If

    Try
        Using fs As New FileStream(Filename, FileMode.Open, FileAccess.Read)
            Dim picByte As Byte() = New Byte(fs.Length - 1) {}
            fs.Read(picByte, 0, System.Convert.ToInt32(fs.Length))
            Using CN As New OleDbConnection(ConnectionString)

                Dim cmd As New OleDbCommand(theQuery, CN)
                cmd.Parameters.Add("Img", OleDbType.Binary).Value = picByte
                cmd.Parameters.Add("@RecordId", OleDbType.Integer).Value = RecordId

                CN.Open()
                cmd.ExecuteNonQuery()
                MessageBox.Show("Image successfully saved.")
            End Using
        End Using

    Catch ex As Exception
        MessageBox.Show(ex.Message)
    End Try

End Sub

兴趣点：

1. 插入和更新现在由相同的方法处理，唯一的区别是布尔参数指定这是新记录还是现有记录。

2. 现在查询不受 sql 注入的影响。这里唯一的连接是你不能在 sql 中参数化的列名，但它是在 sub 本身内部决定的。当你使用 sub 时，你只传递一个布尔值，表明这是一个高分辨率图像。

3. 建议在您使用任何实现 IDisposable 接口的东西时使用 Using 块。即使在抛出异常的情况下，这也可以确保正确关闭和处理。

4. 参数代码简化。