使用经典 ASP 读取 xml 数据答案

【问题标题】：Reading xml data using classic ASP使用经典 ASP 读取 xml 数据
【发布时间】：2012-07-17 12:20:51
【问题描述】：

我写了一段经典asp中读取xml数据的代码如下：

<%


 Dim objxml
    Set objxml = Server.CreateObject("Microsoft.XMLDOM")
    objxml.async = False
    objxml.load ("/abc.in/xml.xml")



set ElemProperty = objxml.getElementsByTagName("Product")
set ElemEN = objxml.getElementsByTagName("Product/ProductCode")
set Elemtown = objxml.getElementsByTagName("Product/ProductName")
set Elemprovince = objxml.getElementsByTagName("Product/ProductPrice")  

Response.Write(ElemProperty)
Response.Write(ElemEN) 
Response.Write(Elemprovince)
For i=0 To (ElemProperty.length -1) 

    Response.Write " ProductCode = " 
    Response.Write(ElemEN) 
    Response.Write " ProductName = " 
    Response.Write(Elemtown) & "<br>"
    Response.Write " ProductPrice = " 
    Response.Write(Elemprovince) & "<br>"

next

Set objxml = Nothing 
%>

此代码没有给出正确的输出。请帮帮我。

xml 是：

<Product>
   <ProductCode>abc</ProductCode>
   <ProductName>CC Skye Hinge Bracelet Cuff with Buckle in Black</ProductName>
</Product>

【问题讨论】：

你能提供一些示例 XML 吗？
abcCC Skye 黑色搭扣铰链手镯袖口
将 xml 添加到问题中，因为 cmets 非常适合它。可以多看一点。

标签： xml asp-classic

【解决方案1】：

试试这个：

<%   

Set objXMLDoc = Server.CreateObject("MSXML2.DOMDocument.3.0")    
objXMLDoc.async = False    
objXMLDoc.load Server.MapPath("/abc.in/xml.xml")

Dim xmlProduct       
For Each xmlProduct In objXMLDoc.documentElement.selectNodes("Product")
     Dim productCode : productCode = xmlProduct.selectSingleNode("ProductCode").text   
     Dim productName : productName = xmlProduct.selectSingleNode("ProductName").text   
     Response.Write Server.HTMLEncode(productCode) & " "
     Response.Write Server.HTMLEncode(productName) & "<br>"   
Next   

%>

注意事项：

不要使用 Microsoft.XMLDOM 使用显式 MSXML2.DOMDocument.3.0
使用Server.MapPath 解析虚拟路径
使用selectNodes 和selectSingleNode 代替getElementsByTagName。 getElementsByTagName 扫描所有后代，因此可能会返回意外结果，然后您始终需要对结果进行索引，即使您知道您只需要一个返回值。
发送到响应时始终Server.HTMLEncode 数据。
不要把 ( ) 放在奇怪的地方，这是 VBScript 而不是 JScript。

【讨论】：

MSXML2.DOMDocument.6.0 调用最新版本

【解决方案2】：

这里是一个如何读取数据的示例，假设 xml 是

<Products>
  <Product> 
    <ProductCode>abc</ProductCode> 
    <ProductName>CC Skye Hinge Bracelet Cuff with Buckle in Black</ProductName> 
  </Product>
  <Product> 
    <ProductCode>dfg</ProductCode> 
    <ProductName>another product</ProductName></Product>
</Products>

以下脚本

<%

Set objXMLDoc = Server.CreateObject("Microsoft.XMLDOM") 
objXMLDoc.async = False 
objXMLDoc.load("xml.xml") 

Set Root = objXMLDoc.documentElement
Set NodeList = Root.getElementsByTagName("Product")

For i = 0 to NodeList.length -1
  Set ProductCode = objXMLDoc.getElementsByTagName("ProductCode")(i)
  Set ProductName = objXMLDoc.getElementsByTagName("ProductName")(i)
  Response.Write ProductCode.text & " " & ProductName.text & "<br>"
Next

Set objXMLDoc = Nothing

%>

给予

abc CC Skye Hinge Bracelet Cuff with Buckle in Black
dfg another product

【讨论】：

这行得通，但使用getElementByTagName 应该敲响警钟，因为它最终会导致痛苦。
不，以这种方式使用getElementByTagName 来纠正问题只是一种严重的痛苦。最好使用selectNodes 和selectSingleNode 导航XML。