创建 #TempTable 时存储过程中的 IF ELSE

Question

我试图让这个存储过程只在函数等于特定 ID 号时返回特定行。例如，if @RentalOnly = 'Y' 则只返回 productID 在 '3367' 或 '3367G' 和 if @RentalOnly = 'N' 中的行，然后返回所有其他不包含此 productID 的行。

这是我目前所拥有的。

alter Procedure [dbo].GetAllProductIDs
    @StartDate datetime,
    @EndDate datetime,
    @RentalOnly char(1)
AS
begin
    SET NOCOUNT ON;

    CREATE TABLE #GetAllProductIDs
    (      
        [Status] nvarchar(30),
        [To Set Date] datetime,
        [Order ID] int,
        [Product ID] nvarchar(10),
        [PPArea] char(2),
        [OrderLineNo] nvarchar(10),
        [OrigSalesman] nvarchar(30),
        [Enterby] int,
        [Rental Month] int,
        [Quantity] int,
        [Quoted$] money,
        [EXT$] money,
        [Mo Base Rental] money,
        [Ext. Base Rental] money,
        [Quoted Mo Rent] money,
        [3367 Total$ vs. Base Total$] money,
        [3367 % Total vs. Base Total] float
    )

    insert #GetAllProductIDs
       exec TempPower_AZ.dbo.GetAllProductIDs @StartDate, @EndDate

    insert #GetAllProductIDs
       exec TempPower_LV.dbo.GetAllProductIDs @StartDate, @EndDate

    insert #GetAllProductIDs
       exec TempPower_OC.dbo.GetAllProductIDs @StartDate, @EndDate

    insert #GetAllProductIDs
       exec TempPower_SD.dbo.GetAllProductIDs @StartDate, @EndDate

    insert #GetAllProductIDs
       exec TempPower_RS.dbo.GetAllProductIDs @StartDate, @EndDate

    if (@RentalOnly = 'Y')
    begin
        Select * 
        from #GetAllProductIDs
        where [Product ID] in ('3367', '3367G')

        return
    end

    if (@RentalOnly = 'N')
    begin
        Select * 
        from #GetAllProductIDs
        where [Product ID] not in ('3367', '3367G')

        return
    end
end

Answer 1

问：我如何让它根据输入到@RentalOnly 的这两个值（'Y' 或'N'）返回行，如果没有输入，它将只返回所有产品 ID

答：要返回所有产品 ID，只需运行不带 WHERE 子句的 SELECT。

但前提是“如果什么都没输入”

@RentalOnly 的哪些值或哪些值可以满足“如果没有输入任何内容”的条件？ NULL 是否满足该条件？空间？ 'W' ？ 'Y' 或 'N' 以外的任何字符？

如果这是我们要实现的逻辑：

IF @RentalOnly is 'Y', return the specified subset from the table
ELSE IF @RentalOnly is 'N', return a different subset from the table
ELSE (for all other values of @RentalOnly) return the whole table

作为如何使用IF...ELSE 块实现该逻辑的示例...

IF (@RentalOnly = 'Y')
  Select * from #GetAllProductIDs where [Product ID] in ('3367', '3367G')
ELSE
  BEGIN
    IF (@RentalOnly = 'N')
      Select * from #GetAllProductIDs where [Product ID] not in ('3367', '3367G')
    ELSE
      Select * from #GetAllProductIDs
  END
RETURN

ELSE 不是绝对必要的。如果我们将条件编码为互斥，我们可以得到等价的结果：

IF (@RentalOnly = 'Y')
  Select * from #GetAllProductIDs where [Product ID] in ('3367', '3367G')
IF (@RentalOnly = 'N')
  Select * from #GetAllProductIDs where [Product ID] not in ('3367', '3367G')
IF (@RentalOnly IS NULL OR @RentalOnly NOT IN ('Y','N')
  Select * from #GetAllProductIDs
RETURN

正如 DavidG 在他的回答中指出的那样，完全没有必要使用 IF。可以将“if else”逻辑移到单个 SELECT 语句的 WHERE 子句中。例如：

Select * from #GetAllProductIDs
 WHERE ( @RentalOnly IN ('Y') AND [Product ID] IN ('3367', '3367G') )
    OR ( @RentalOnly IN ('N') AND [Product ID] NOT IN ('3367', '3367G') ) 
    OR ( @RentalOnly NOT IN ('Y','N') OR @RentalOnly IS NULL )
RETURN

Answer 2

我会完全放弃IF/ELSE 逻辑，只需在一个查询中完成所有操作，如下所示：

SELECT
    *
FROM 
    #GetAllProductIDs
WHERE 
    (@RentalOnly = 'Y' AND productID IN ('3367', '3367G')) 
OR  (@RentalOnly = 'N' AND productID NOT IN ('36367, '3367G'))