SQL Server 2000 中的行到列

Question

我有这个..

IDProspecto | IDObservacionCustomer | Observacion
---------------------------------------------------------    
  2204078   | 275214                | 03/9 Hable con Claudia me informa que Roberto ya se termino le deje..
  2204078   | 294567                | 19/09 SOLICITAN LLAME MAÑANA A ALEJANDRO   
  2204078   | 295310                | 20/09 se envia mail a adrian 
  2204078   | 304102                | CIA SOLICITA NO INSTALE EQUIPO  

我想要这个……

idprospecto | observacion1            | observacion2            | observacion3      | observacion4 | observacionN
-----------------------------------------------------------------------------------------    
  2204078   | 03/09 Hable con clau... | 19/09 solicitan llame... | 20/09 se envia... | CIA solicita..   | ...

我阅读了很多关于这方面的内容，但我发现它很难实现，因为我从未使用过游标，并且 SQL Server 2000 中不提供数据透视表，我希望这里有人可以帮助我，谢谢。

Answer 1

由于 SQL Server 2000 没有PIVOT 函数，您应该可以使用类似于以下的内容：

DECLARE @query AS NVARCHAR(4000)
DECLARE   @rowCount as int
DECLARE   @pivotCount as int
DECLARE   @pivotRow as varchar(10)

set @rowCount = 1
set @pivotRow = ''

create table #colsPivot
(
  id int IDENTITY(1,1),
  name varchar(20),
  CustId int
)

insert into #colsPivot
select 'Observacion', IDObservacionCustomer
from yourtable

set @pivotCount= (select COUNT(*) from #colsPivot) 

-- reset rowcount
set @rowCount = 1
set @query = ''

---- create the CASE string
while @rowCount <= @pivotCount
    begin
        set @pivotRow = (select Top 1 CustId from #colsPivot)

        set @query = @query + ', max(case when IDObservacionCustomer = ''' + @pivotRow + ''' then Observacion end) as ''Observacion_' + cast(@rowCount as varchar(10)) + ''''

        delete from #colsPivot where CustId = @pivotRow

        if @rowCount <= @pivotCount
            begin
                set @rowCount = @rowCount + 1
            end
    end

-- add the rest of the SQL Statement
set @query = 'SELECT IDProspecto ' + @query + ' from yourtable group by IDProspecto'

exec(@query)

见SQL Fiddle With Demo

Answer 2

你可以试试这个例子。

准备数据：

create table tab1
(
  IDProspecto  int,
  IDObservacionCustomer int, 
  Observacion varchar(130)
)    

insert into tab1
values (2204078,275214 ,'03/9 Hable con Claudia me informa que Roberto ya se termino le deje..' )

insert into tab1
values (2204078,294567   ,'19/09 SOLICITAN LLAME MAÑANA A ALEJANDRO   ' )

insert into tab1
values (2204078,295310 ,'20/09 se envia mail a adrian' )

insert into tab1
values (2204078,304102 ,'CIA SOLICITA NO INSTALE EQUIPO' )

我们需要identity 字段，所以我创建新表，并从tab1 复制数据。

create table tab2
(
  id int identity,  
  IDProspecto  int,
  IDObservacionCustomer int, 
  Observacion varchar(130)
)

insert into tab2(IDProspecto,IDObservacionCustomer,Observacion)
select IDProspecto,IDObservacionCustomer,Observacion from tab1

运行查询：

declare @max int, @inc int, @SqlSel varchar(2000),@SqlJoin varchar(2000), @Sql varchar(2000)

select @max = max(cnt) from (
select count(1) as cnt
  from tab1
) T

select @inc = 1
select @SqlSel = 'select distinct t.IDProspecto '
select @SqlJoin = 'from tab2 t'
while @max>=@inc
begin
  select @SqlSel= @SqlSel+', tab2'+convert(varchar,@inc)+'.Observacion as o'+convert(varchar,@inc)
  select @SqlJoin = @SqlJoin+' left join tab2 as tab2'+convert(varchar,@inc)+' on t.IDProspecto = tab2'+convert(varchar,@inc)+'.IDProspecto and  tab2'+convert(varchar,@inc)+'.id='+convert(varchar,@inc)
  select @inc=@inc+1
end

select @SqlSel, @SqlJoin

exec( @SqlSel+' '+ @SqlJoin)