存储过程中的 sp_rename 不起作用

Question

以下 3 个语句在连续执行时工作正常，但当我将它们包装在一个存储过程中时，我收到此错误消息：

消息 207，第 16 级，状态 1，第 10 行
列名“拆分”无效。
消息 207，第 16 层，状态 1，第 9 行
列名“拆分”无效。

程序定义：

CREATE procedure [dbo].[dsplit_SITEL_update]
as
begin
   set nocount on;

   IF EXISTS(SELECT * FROM sys.columns 
             WHERE [name] = N'split_' AND [object_id] = OBJECT_ID(N'dsplit_SITEL$'))

       exec sp_rename @objname = N'dsplit_SITEL$.split_', 
                      @newname = 'split', 
                      @objtype = 'COLUMN';

   insert into dsplit_SITEL
      select 
          CONVERT(varchar(10), b.row_date, 120) + '_' + CONVERT(nvarchar(10), b.split), 
          b.*
      from dsplit_SITEL a 
      right join dsplit_SITEL$ b ON a.pk = CONVERT(varchar(10), b.row_date, 120) + '_' + CONVERT(nvarchar(10), b.split)
      where a.pk is null and b.row_date is not null;

    if OBJECT_ID('dsplit_SITEL$', 'U') is not null
       drop table dsplit_SITEL$;
END

这里发生了什么，我怎样才能使程序正常工作？

Answer 1

嗯，问题是在创建时 SQL Server 尝试将名称绑定到对象。如果该表目前不存在，那很好（这称为延迟名称解析）。但是，如果表存在但列不存在，则会失败并出现“列名无效”错误。

如果您使 SQL 动态化，您可以解决此问题，至少部分使用重命名的列，如下所示：

declare @s nvarchar(4000)
set @s = N'
    insert into dsplit_SITEL
    select 
        CONVERT(varchar(10), b.row_date, 120) + ''_'' + CONVERT(nvarchar(10), b.split), 
        b.*
    from dsplit_SITEL a 
    right join dsplit_SITEL$ b ON a.pk = CONVERT(varchar(10), b.row_date, 120) + ''_'' + CONVERT(nvarchar(10), b.split)
    where a.pk is null and b.row_date is not null;
'
exec (@s)