子查询返回多个值？答案

【问题标题】：Subquery returns more than one value?子查询返回多个值？
【发布时间】：2020-07-08 17:30:41
【问题描述】：

我正在尝试使用我编写的存储过程，它应该在“项目”表中创建一个新项目。它还会检查“已保存项目”表中是否存在具有相同 ID 的已保存项目，并在成功创建后将其删除。

还要检查传递的user_id是否有实际创建项目的权限（即不是标准用户）。

这是存储过程：

USE [BugMate_DB]
GO
/****** Object:  StoredProcedure [dbo].[create_project]    Script Date: 2020-07-08 11:05:30 AM ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER PROCEDURE [dbo].[create_project]
    @project_name NVARCHAR(40),
    @date_started DATETIME,
    @project_description NVARCHAR(400),
    @project_status NVARCHAR(40),
    @project_active BIT,
    @next_iteration_date DATETIME,
    @created_by_userid INT,
    @project_leader_id INT,
    @save_id INT = NULL
AS

SET NOCOUNT ON

BEGIN
    IF (SELECT TOP 1 roleid from user_info WHERE userid = @created_by_userid) = 'SDU'
    BEGIN
            RAISERROR ('User does not have permission to do this action. Please contact a manager or administrator to resolve this issue.', 16, 1)
    END

    ELSE
    BEGIN
            INSERT INTO project(project_name, date_started, project_description, project_status, project_active, next_iteration_date, created_by_userid, project_leader_id)
            VALUES (@project_name, @date_started, @project_description, @project_status, @project_active, @next_iteration_date, @created_by_userid, @project_leader_id)

            IF @@ERROR <> 0
            BEGIN
                    RAISERROR('Project creation insert failed.', 16, 1)
            END
            ELSE
                BEGIN
                    IF @save_id != NULL
                    BEGIN
                        IF EXISTS (SELECT TOP 1 save_id FROM saved_project WHERE save_id = @save_id)
                        BEGIN
                                DELETE FROM saved_project WHERE save_id = @save_id
                        END
                    END         
                END
        END

        IF @@ERROR <> 0
        BEGIN
                RAISERROR('Error creating project', 16, 1)
        END
        ELSE
        BEGIN
                INSERT INTO project_member(userid, project_number)
                VALUES (@created_by_userid, (SELECT project_number FROM project WHERE created_by_userid = @created_by_userid))
        END
END

问题是我在执行我的 SP 时收到此错误：

消息 512，级别 16，状态 1，过程 create_project，第 48 行子查询返回超过 1 个值。当子查询跟随 =、!=、、>= 或子查询用作表达式时，这是不允许的。

我不确定为什么我的任何子查询都会返回多个值。

这是我试图传递的值：

USE [BugMate_DB]
GO

DECLARE @return_value int

EXEC    @return_value = [dbo].[create_project]
        @project_name = N'Test',
        @date_started = N'12/25/2015 12:00:00 AM',
        @project_description = N'This is a test.',
        @project_status = N'InDevelopment',
        @project_active = 1,
        @next_iteration_date = N'12/25/2015 12:00:00 AM',
        @created_by_userid = 19,
        @project_leader_id = 19,
        @save_id = NULL

SELECT  'Return Value' = @return_value

GO

我曾尝试使用“TOP 1”来尝试获取单个值，但它似乎不是我想要的。

据我所知，这也不是连接问题。

我是 SQL Server 新手，因此我们将不胜感激。

【问题讨论】：

过程中的最后一条语句就是问题所在。并且评论“......似乎不是我要寻找的”对你来说是有意义的，对其他人来说没有意义。您要使用的逻辑很可能是不正确的——随着时间的推移，同一个人肯定可以创建多个项目。并且您不能使用相等运算符将任何内容与 NULL 进行比较。为此，您必须使用 ISNULL。
读心术 - project_number 是一个身份列吗？
还有另一个缺陷 - 使用没有 order by 子句的 TOP 只会限制结果集中的行数。它不保证选择任何特定行。您应该将其替换为 EXISTS - 但这在逻辑上也可能不正确。
project_number 是标识列。我应该澄清一下，同一个人可以创建多个项目，检查“ IF (SELECT TOP 1 roleid from user_info WHERE userid = @created_by_userid) = 'SDU'”是为了验证用户的权限级别。感谢您的帮助@SMor

标签： sql sql-server database stored-procedures subquery

【解决方案1】：

尝试更改此设置

IF ( SELECT TOP 1 roleid from user_info WHERE userid = @created_by_userid ) = 'SDU'
BEGIN
    RAISERROR ( 'User does not have permission to do this action. Please contact a manager or administrator to resolve this issue.', 16, 1 )
END

到

IF NOT EXISTS ( SELECT * FROM user_info WHERE userid = @created_by_userid AND roleid = 'SDU' )
BEGIN
    RAISERROR ( 'User does not have permission to do this action. Please contact a manager or administrator to resolve this issue.', 16, 1 )
END

编辑：包括明确的角色访问权限。

IF NOT EXISTS ( SELECT * FROM user_info WHERE userid = @created_by_userid AND roleid IN ( 'SDU', 'MNG', 'ADM ' ) )
BEGIN
    RAISERROR ( 'User does not have permission to do this action. Please contact a manager or administrator to resolve this issue.', 16, 1 )
END

更新：

USE [BugMate_DB]
GO

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

ALTER PROCEDURE [dbo].[create_project]
    @project_name NVARCHAR(40),
    @date_started DATETIME,
    @project_description NVARCHAR(400),
    @project_status NVARCHAR(40),
    @project_active BIT,
    @next_iteration_date DATETIME,
    @created_by_userid INT,
    @project_leader_id INT,
    @save_id INT = NULL
AS
BEGIN

    SET NOCOUNT ON;
    DECLARE @err INT = 0;
    DECLARE @output TABLE ( project_number INT );

    IF NOT EXISTS ( SELECT * FROM user_info WHERE userid = @created_by_userid AND roleid IN ( 'SDU', 'MNG', 'ADM ' ) )
    BEGIN
            RAISERROR ( 'User does not have permission to do this action. Please contact a manager or administrator to resolve this issue.', 16, 1 );
    END
    ELSE
    BEGIN

        INSERT INTO project (
            project_name, date_started, project_description, project_status, project_active, next_iteration_date, created_by_userid, project_leader_id
        )
        OUTPUT inserted.project_number INTO @output
        VALUES (
            @project_name, @date_started, @project_description, @project_status, @project_active, @next_iteration_date, @created_by_userid, @project_leader_id
        );

        -- Capture error value.
        SET @err = @@ERROR;

        IF @err <> 0
        BEGIN
                RAISERROR ( 'Project creation insert failed.', 16, 1 );
        END
        ELSE
        BEGIN

            IF @save_id IS NULL
            BEGIN

                IF EXISTS ( SELECT * FROM saved_project WHERE save_id IS NULL )
                BEGIN
                    DELETE FROM saved_project WHERE save_id IS NULL;
                END
            
            END         

        END

    END

    IF @err <> 0
    BEGIN
        RAISERROR ( 'Error creating project', 16, 1 );
    END
    ELSE
    BEGIN

        INSERT INTO project_member ( 
            userid, project_number
        )
        VALUES (
            @created_by_userid, 
            ( SELECT project_number FROM @output )
        );

    END

END

【讨论】：

我试过了，但我应该澄清我想通过这个检查来实现什么。我想拥有 3 种具有不同权限级别的用户。从最低到最高依次是：SDU、MNG、ADM 或标准用户、经理、管理员。我想检查尝试创建项目的用户是否不是标准用户，因为他们没有创建项目的权限。感谢您的帮助。
假设我理解你所说的，看看我上面的编辑。
我已将代码更改为您建议的内容，我认为您的回答是有道理的，但我仍然收到原始错误。我认为问题出在我的代码某处，因为如果我传递无权创建项目的用户的 user_id，它会触发错误消息，指出他们没有权限并且语句终止；但是，如果他们确实有权限，则错误保持不变，即子查询返回多个值。
我想我找到了你的问题，@Chris。查看我对您的 SP 的更新。
是的，这已解决，谢谢！下面的@TAirlines 也让我走上了这条路。我的最后一条语句是返回我的“项目”表中的所有值，因此“返回多个值”。我使用了“ IDENT_CURRENT('project') ”。我很困惑，因为我假设项目没有被创建，因为我得到了子查询错误，但看起来它们是，并且错误出现在您在上面修复的语句中。我不确定哪一个更好，但你的回答对我来说更有意义，所以我会使用那个。再次感谢！

【解决方案2】：

请使用IS NULL 比较NULL 的值，如下所示：

IF @save_id IS NULL

或

IF @save_id IS NOT NULL

【讨论】：

谢谢，我会改的。

【解决方案3】：

我之前没见过这种类型的查询

INSERT INTO project_member(userid, project_number)
VALUES (@created_by_userid, 
(SELECT project_number FROM project WHERE created_by_userid = @created_by_userid))

我也愿意

INSERT INTO project_member(userid, project_number)
VALUES (@created_by_userid, @project_id)

如果我只是插入 2 个值。

如果插入许多值，我会使用SELECT 而不是VALUES。

如果我插入的值可能超过 1 行：

INSERT INTO project_member(userid, project_number)
SELECT created_by_userid, project_number FROM project
WHERE created_by_userid = @created_by_userid

我只是猜测，因为那大约是第 46 行

另外，sacse 对 IF (@save_id IS NULL) 的评价是什么

也许在某个地方有答案

【讨论】：

这不是我的问题，但它让我走上了正轨。谢谢你的帮助！答案在上面。