SQL Server 如何将列名链接到外部变量？

Question

我在SQL中做了一个代码，将一个项目与一列的每条记录分开而不重复，并且它工作正常，请按照以下代码：

SELECT DISTINCT Tab_Dados_Escolha.Nome_Produto FROM Tab_Dados_Escolha

但是我想用一个外部变量替换这个例程将在其中完成的列的名称，所以我可以对其他列使用相同的代码，而不必重写另一个代码，我无法做到这一点到目前为止，有人可以帮助我吗？

Answer 1

我正在回答这里提出的问题，但是，正如我所提到的，它具有XY Problem 的外观和“气味”。因此，您真的应该询问您真正想要解决的问题，并且应该（现在）在一个新问题中。

至于您所问的，正如 cmets 告诉您的那样，您不能使用变量/参数来替换列文字。采取如下方式：

DECLARE @ColName sysname;
SET @ColName = N'Nome_Produto';

SELECT DISTINCT @ColName
FROM dbo.Tab_Dados_Escolha;

这不会为Nome_Produto 列中的每个不同值返回一行。相反，它将返回值为N'Nome_Produto' 的单行和列。就是这样。这是因为变量/参数没有被解释为“返回具有@ColName 值的列的值”，而只是“返回@ColName 的值”。

因此，您需要使用动态 SQL 并安全地注入值。我还建议验证传递的值，这样如果该列不存在，您就不会运行任何（动态）SQL。这意味着您需要执行以下操作：

DECLARE @Colname sysname; --Your Parameter
SET @ColName = N'Nome_Produto'; --Parameter Value

DECLARE @SQL nvarchar(MAX);

SELECT @SQL = N'SELECT DISTINCT ' + QUOTENAME(c.[name]) + N' FROM dbo.Tab_Dados_Escolha;'
FROM sys.schemas s
     JOIN sys.tables t ON s.schema_id = t.schema_id
     JOIN sys.columns c ON t.object_id = c.object_id
WHERE s.[name] = N'dbo' --assumed
  AND t.[name] = N'Tab_Dados_Escolha'
  AND c.[name] = @Colname;

EXEC sys.sp_executesql @SQL;

当然，这些都没有涉及动态 SQL 的参数化等，但这也是一个非常不同的问题。

但是，除非您真的知道自己在用它做什么，否则真的不推荐使用动态 SQL。如果你连这么简单的东西都不懂，就不要使用它。相反，请重新考虑您的设计，因为它可能存在缺陷。