将数据加载到 DataGridViewComboBoxColumn VB.NET

Question

嗨，我整天都在用头撞墙试图弄清楚这一点。

我有一个显示 SQL 查询结果的 DataGridView

查询返回 3 个字段：GROUPNUM、GROUPNAME、COACHING

组字段中只有字符串并且它们显示正常，但 COACHING 字段是一个单字符字段，其中包含 Y 或 N。对于该列，我希望有一个以 Y 或 N 作为项目的组合框。这是我目前所拥有的。

dtGroups 是一个用 SQL 数据适配器填充的数据表。

            dvGroups = dtGroups.DefaultView

            'Set up datagrid view

            With dgvToPopulate

                .Columns.Clear()

                .AutoGenerateColumns = False
                .AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.AllCells
                .AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.AllCells

                .DataSource = dtGroups

                With .Columns

                    Dim groupNumColumn, groupNameColumn As New DataGridViewTextBoxColumn

                    With groupNumColumn

                        .DataPropertyName = "GROUPNUM"
                        .HeaderText = "Group Number"
                        .ReadOnly = True

                    End With

                    With groupNameColumn

                        .DataPropertyName = "GROUPNAME"
                        .HeaderText = "Group Name"
                        .ReadOnly = True

                    End With

                    Dim coachingColumn As New DataGridViewComboBoxColumn

                    With coachingColumn

                        .HeaderText = "RN Coaching"

                        .Items.AddRange({"Y", "N"})

                        .DataPropertyName = "COACHING"

                        .DisplayMember = .DataPropertyName
                        .ValueMember = .DisplayMember


                    End With

                    .AddRange({groupNumColumn, groupNameColumn, coachingColumn})

                End With

            End With

网格按照我想要的方式设置，它显示了除了所有组合框之外的所有数据，没有任何选择。如何根据该字段中存储的内容让组合框在其中包含 Y 或 N。

对此的任何帮助将不胜感激。

Answer 1

DisplayMember 和 ValueMember 都链接到 DataSource 属性。每当您更改这些属性之一时，都会重置数据连接。换句话说：items-collection 被清除了。

以你的例子为例。 String 类没有名为 COACHING 的成员。它具有Length 和Chars 等属性。因此您无法创建绑定。此外，items-collection 接受所有类型的对象。

您需要创建和绑定自定义数据源。这是一个使用 DataTable 的示例：

Dim ynTable As New DataTable()

With ynTable
    .Columns.Add("Value", GetType(String))
    .Rows.Add("Y")
    .Rows.Add("N")
    .AcceptChanges()
End With

With coachingColumn
    .HeaderText = "RN Coaching"
    .DataSource = ynTable
    .DataPropertyName = "COACHING"
    .DisplayMember = "Value"
    .ValueMember = "Value"
End With