在一个表单内的 Access 中的三个子表单中显示基于相同 id 的记录

Question

我知道我正在寻找快速解决方案，主要问题在于数据库设计，但目前我对此无能为力。

这是我的愿望：

我有三个表 TableA、TableB、TableC，它们都共享 ID 作为键并打开了引用完整性（事实上，这将是一个包含超过 255 列的大表，这是我必须找到解决方法的限制）。我想要实现的是将所有记录同时显示为彼此相邻的数据表，并具有以下行为：

• 如果我在表 A 中过滤，表 B 和 C 应该显示相同的行
• 排序也应该相等，并且应该由表 A 中的某些列完成
• 我已经设法将光标放在所有表的同一行中

我想过在该记录集上创建一个select * from tableB where id in filteredrecordset of tableA 或某种形式的连接，但没有成功。

附带说明：该数据库中有大约 10 万条记录，性能必须很快，因为该视图主要用于需要这种扁平数据结构的多列和多行的数据输入/更新。

提前感谢您的帮助！

Answer 1

您可以使用表单On Filter 事件来同步过滤器。但是，我假设您已将子表单直接绑定到表格。

因为您已将子表单直接绑定到表格，所以您无法监听事件。但是，我最近 encountered that issue，并且有一个 hacky 解决方法，但如果您的字段名称和表名称是恒定的，则不需要使用它。您只需要将 TableA 包装在数据表中即可。

打开TableA，进入创建选项卡，然后More Forms -> Datasheet。您现在有一个数据表表单，它捕获了 TableA 中的所有字段。然后，向该数据表表单添加一个模块。您不需要该模块中的任何代码。

然后，我们没有将第一个子表单绑定到TableA，而是将其绑定到这个数据表表单。

现在，在父表单上，我们将为过滤器设置一个事件处理程序。

在父窗体上（我假设你的子窗体控件的名称为 tableA 是 SubA，对于 tableB SubB，对于 TableC SubC）：

Private WithEvents tblAForm As Form 'Declare tblAForm to handle events

Private Sub Form_Load()
    'Initialize event handler, sync initially
    Set tblAForm = Me.Controls("subA").Form
    tblAForm.OnApplyFilter = "[Event Procedure]"
    SyncFilters 'Not needed if you're not persisting filters, which you likely aren't
End Sub

Private Sub tblAForm_ApplyFilter(Cancel As Integer, ApplyType As Integer)
    'Sync filters
    SyncFilters(ApplyType)
End Sub

Private Sub SyncFilters(ApplyType As Integer)
    Dim srcB As String
    Dim srcC As String
    Dim strFilter As String
    Dim strOrder As String
    'If filter or sort are on on TableA, we need to join in TableA for sorting and filtering
    If tblAForm.FilterOn  Or tblAForm.OrderByOn Then
        srcB = "SELECT TableB.* FROM TableB INNER JOIN TableA On TableA.ID = TableB.ID"
        srcC = "SELECT TableC.* FROM TableC INNER JOIN TableA On TableA.ID = TableC.ID"
        'Filter to SQL
        strFilter = " WHERE " & tblAForm.Filter
        'Sort to SQL
        strOrder = " ORDER BY  " & tblAForm.OrderBy
        If tblAForm.FilterOn And tblAForm.Filter & "" <> "" And ApplyType <> 0 Then
            'If the filter is on, add it
            srcB = srcB & strFilter
            srcC = srcC & strFilter
        End If
        If tblAForm.OrderByOn And tblAForm.OrderBy & "" <> "" Then
            'If order by is on, add it
            strB = srcB & strOrder
            srcC = srcC & strOrder
        End If
    Else
        srcB = "SELECT TableB.* FROM TableB"
        srcC = "SELECT TableC.* FROM TableC"
    End If
    If srcB <> Me.SubB.Form.RecordSource Then Me.SubB.Form.RecordSource = srcB
    If srcC <> Me.SubC.Form.RecordSource Then Me.SubC.Form.RecordSource = srcC
End Sub

请注意，您确实需要一些备用字段来进行过滤和排序。用于此的任何字段都计入最多 255 个字段。如果您可能会遇到这种情况，您可以考虑将数据集拆分为 4 个表而不是 3 个

Answer 2

考虑使用 RecordSourceClone 属性和运行以下例程的 ID 临时表：

1. On Exit 过滤后的任何子表单，ID 都会迭代地附加到临时表中。
2. 其他两个子表单的 RecordSources 过滤为临时表 ID。
3. 重置按钮会删除所有过滤器以运行不同的条件。

VBA

Option Compare Database
Option Explicit

' RESET ALL SUBFORMS
Private Sub RESET_Click()
    Me.Controls("frm_TableA").Form.RecordSource = "TableA"
    Me.Controls("frm_TableB").Form.RecordSource = "TableB"
    Me.Controls("frm_TableC").Form.RecordSource = "TableC"
End Sub

Private Sub frm_TableA_Exit(Cancel As Integer)
    Call RunFilters("frm_TableA", "frm_TableB", "frm_TableC")
End Sub

Private Sub frm_TableB_Exit(Cancel As Integer)
    Call RunFilters("frm_TableB", "frm_TableA", "frm_TableC")
End Sub

Private Sub frm_TableC_Exit(Cancel As Integer)
    Call RunFilters("frm_TableC", "frm_TableA", "frm_TableB")
End Sub

Function RunFilters(curr_frm As String, frm1 As String, frm2 As String)
On Error GoTo ErrHandler

    Dim rst As Recordset, tmp As Recordset

    ' DELETE PREVIOUS TEMP
    CurrentDb.Execute "DELETE FROM IDTempTable", dbFailOnError
    Set tmp = CurrentDb.OpenRecordset("IDTempTable")

    ' RETRIEVE FILTERED FORM RECORDSOURCE
    Set rst = Me.Controls(curr_frm).Form.RecordsetClone

    ' ITERATIVELY ADD IDs
    Do While Not rst.EOF
        With tmp
            .AddNew
                !ID = rst![ID]
            .Update
            rst.MoveNext
        End With
    Loop

    tmp.Close: rst.Close
    Set tmp = Nothing: Set rst = Nothing

    ' FILTER OTHER FORMS
    Me.Controls(frm1).Form.RecordSource = "SELECT * FROM " & Replace(frm1, "frm_", "") & _
                                            &  " WHERE [ID] IN (SELECT ID FROM IDTempTable)"
    Me.Controls(frm2).Form.RecordSource = "SELECT * FROM " & Replace(frm2, "frm_", "") & _
                                            & " WHERE [ID] IN (SELECT ID FROM IDTempTable)"        
ExitHandler:
    Exit Function

ErrHandler:
    MsgBox Err.Number & " - " & Err.Description, vbCritical, "RUN-TIME ERROR"
    Resume ExitHandler
End Function