DoCmd.TransferSpreadsheet 问题

Question

我在 Access 2013 中将查询导出到 Excel。这是我用于导出的语法

DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel12Xml, "qryDataExport", strExportPath, True

数据按应有的方式传输，但查询中的字段之一标题为 Player #，导出到 Excel 时变为 Player .

如何在导出时保持# 完好无损？

Answer 1

虽然DoCmd.TransferSpreadsheet 可以重现问题，但请考虑DoCmd.OutputTo，它保留了查询的格式。前一种方法可能更侧重于电子表格格式。

事实上，DoCmd.OutputTo 看起来是外部数据\Excel 导出功能区方法的自动化版本（选择保留所有格式）：

DoCmd.OutputTo acOutputQuery, "qryDataExport", acFormatXLSX, strExportPath

Answer 2

您可以使用以下函数将内容导出到 .xlsx 文件，而不必处理 DoCmd.TransferSpreadsheet 的限制

Public Sub CustomExcelExport(QueryOrTableOrSQL As String, FileLocation As String)
    Dim rs As DAO.Recordset
    Dim excelApp As Object
    Set excelApp = CreateObject("Excel.Application")
    Set rs = CurrentDb.OpenRecordset(QueryOrTableOrSQL)
    excelApp.Workbooks.Add
    Dim colNo As Long: colNo = 1
    Dim rowNo As Long: rowNo = 1
    Dim fld As Variant

    For Each fld In rs.Fields
        excelApp.Cells(rowNo, colNo) = fld.Name
        colNo = colNo + 1
    Next fld
    Do While Not rs.EOF
       colNo = 1
       rowNo = rowNo + 1
       For Each fld In rs.Fields
            excelApp.Cells(rowNo, colNo) = fld.Value
            colNo = colNo + 1
       Next fld
       rs.MoveNext
    Loop
    excelApp.ActiveWorkbook.SaveAs FileLocation, 51 'xlOpenXMLWorkbook
    excelApp.Quit
End Sub

打电话给：CustomExcelExport "qryDataExport", strExportPath