Excel UDF 接受范围和数组作为参数，如“SUM”

Question

我正在编写一个需要同时接受数组和范围的 UDF。

通常将参数声明为变体会起作用，但 Range 是一个对象，因此不再适用。话虽如此，我粘贴了仅在传递数组时才有效的代码。
这是基于SUM的理论示例：

Function TSUM(numbers() As Variant) As Variant
    Dim i As Integer
    For i = 1 To UBound(numbers, 1)
        TSUM = TSUM + numbers(i)
    Next i
End Function

=TSUM({1,1}) 返回 2
=TSUM(A1:B1) 返回#VALUE！

那么我怎样才能修复上面的例子来接受范围呢？

Answer 1

如果您满足于逐项对数组/范围求和，我会改为使用适用于范围或数组的 For Each 循环。

这是那个版本

Public Function TSUM(numbers As Variant) As Variant
    Dim i As Variant

    For Each i In numbers
        TSUM = TSUM + i
    Next i
End Function

如果您通常希望根据参数的类型来处理函数，您可以使用TypeName() 和切换逻辑。这是您使用这种方法的功能。我称它为 TSUM2 是因为它的独特性。

Public Function TSUM2(numbers As Variant) As Variant
    Dim i As Integer

    If TypeName(numbers) = "Range" Then
        TSUM2 = Application.WorksheetFunction.Sum(numbers)
    Else
        For i = 1 To UBound(numbers, 1)
            TSUM2 = TSUM2 + numbers(i)
        Next i
    End If
End Function

请注意，在这两个示例中，我从数字参数中删除了括号（之前是 numbers() as Variant）。这允许它接受范围输入。

如果您采用第二种方法，请务必调试并验证可能通过的 TypeName。