工作表循环用户定义的功能故障

Question

我正在一个包含多个选项卡的工作簿上用 Excel 编写一些 VBA 代码，其中大部分都包含一个表格。我正在创建一个用户定义的函数来计算每个工作表上单个列中给定输入组合（两个输入）的所有实例。我意识到可能有一个非 vba 解决方法，但我希望在进行更新时尽可能少地手动操作此工作簿。目前它不包含很多单元格，但它可能会向前发展。

例如：给定“质量”和“立即到期”，我想计算在每个工作表的给定列中存在多少作为“质量：立即到期”的这种组合的实例。然后，应在特定单元格中调用函数的初始工作表（即摘要页面）上将总数作为整数输出。

我在一些事情上四处寻找帮助，但我的函数不断收到“#VALUE”错误，我目前无法弄清楚。我对 VBA 还是较新，所以如果我做了一些愚蠢的事情，请给我一些解释。我会很感激的！

这是我的模块：

Function StatusCounterByDepartment(Department As String, Status As String)
    Dim Counter As Integer: Counter = 0

    For i = 2 To ThisWorkbook.Sheets.Count
        ThisWorkbook.Sheets(i).Activate
        For j = 2 To ActiveSheet.ListObjects(1).Rows.Count
            If (ActiveSheet.Range("H" & j).Value = Department & ": " & Status) Then
                Counter = Counter + 1
            End If
        Next j
    Next i

    StatusCounterByDepartment = Counter
End Function

我的思考过程是循环浏览给定的列，直到该列的长度结束，评估它是否符合我的标准，为活动工作表中的每个实例添加 1 到我的计数器，然后循环浏览我的其余部分工作表，直到我得到最终计数。然后，将最终计数报告为我的函数的返回值。

感谢您提供的任何帮助！

Answer 1

这根本不可靠，但我只是在修复最初的东西。您可能希望添加适当的错误处理来处理不存在的表作为附加操作的示例。

Public Sub count()

MsgBox StatusCounterByDepartment("Quality", "Due Immediately")

End Sub

Public Function StatusCounterByDepartment(ByVal Department As String, ByVal Status As String) As Long
    Dim Counter As Long
    Counter = 0

    For i = 2 To ThisWorkbook.Sheets.count

       With ThisWorkbook.Sheets(i)

           On Error Resume Next

           For j = 2 To (1 + .ListObjects(1).DataBodyRange.Rows.count)

               If (.Range("H" & j).Value = Department & ": " & Status) Then
                   Counter = Counter + 1
               End If

           Next j

           On Error GoTo 0

        End With

    Next i

    StatusCounterByDepartment = Counter
End Function