德尔福Firedac大师详解多项

Question

我在 2 个 tdbgrid 中显示了 2 个关系主详细信息表。现在 我想在 Tedit 控件中的表格详细信息的行上显示每个字段，但现在我只查看第一组 tedit 中的第一行详细信息。

enter image description here

Answer 1

如果这是一个 VCL 项目（而不是 FireMonkey 项目），您可以非常简单地做到这一点。

• 在表单上放置一个 TDBCtrlGrid 并为详细数据集设置其 DataSource。

• 在 IDE 中，DBCtrlGrid 将显示一系列垂直面板，其中一个为纯灰色，其他为条纹。将 db-aware 控件（如 TDBEdits）放在实心灰色面板上，设置其 DataField 属性，然后编译并运行。 DBCtrlGrid 有一个Orientation 属性，您可以根据自己的喜好将其设置为垂直或水平。

您应该看到，在运行时，DBCtrlGrid 填充了与详细记录一样多的面板实例和它包含的 db 感知组件，最多由 DBCtrlGrid 的 RowCount 属性指定的数量。如果要确保有足够的面板副本，可以尝试将RowCount 值设置为主数据集的RecordCount' of the detail dataset in theAfterScroll` 事件。

另一方面，如果它是一个 FireMonkey (FMX) 项目，因此您需要使用 LiveBindings（没有 TDBCtrlGrids），它可能可以按照与您类似的方式执行此操作会设置控件来显示主数据集的字段，但我从未尝试过。

以下最小的 VCL 项目代码摘录显示了 DBCtrlGrid 的使用；

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls, DBCtrls, Grids, DBGrids, DB, DBClient,
  dbcgrids, Mask;

type
  TForm1 = class(TForm)
    cdsMaster: TClientDataSet;
    cdsDetail: TClientDataSet;
    dsMaster: TDataSource;
    dsDetail: TDataSource;
    gMaster: TDBGrid;
    dbnavMaster: TDBNavigator;
    gDetail: TDBGrid;
    dbnavDetail: TDBNavigator;
    DBCtrlGrid1: TDBCtrlGrid;
    DBEdit1: TDBEdit;  // placed in DBCtrlGrid1
    DBEdit2: TDBEdit;  // placed in DBCtrlGrid1
    procedure cdsMasterAfterScroll(DataSet: TDataSet);
    procedure FormCreate(Sender: TObject);
  private
  public
  end;

[...]

procedure TForm1.FormCreate(Sender: TObject);
var
  i,
  j : Integer;
  Field : TIntegerField;
begin
  DBEdit1.DataField := 'MasterID';
  DBEdit2.DataField := 'DetailID';

  Field := TIntegerField.Create(Self);
  Field.FieldName := 'MasterID';
  Field.DataSet := cdsMaster;
  cdsMaster.CreateDataSet;

  Field := TIntegerField.Create(Self);
  Field.FieldName := 'DetailID';
  Field.DataSet := cdsDetail;
  Field := TIntegerField.Create(Self);
  Field.FieldName := 'MasterID';
  Field.DataSet := cdsDetail;

  cdsDetail.MasterSource := dsMaster;
  cdsDetail.MasterFields := 'MasterID';
  cdsDetail.IndexFieldNames := 'MasterID;DetailID';
  cdsDetail.CreateDataSet;

  for i := 1 to 10 do begin
    cdsMaster.InsertRecord([i]);
    for j := 1 to i do
      cdsDetail.InsertRecord([j, i]);
  end;
  cdsMaster.First;
end;

procedure TForm1.cdsMasterAfterScroll(DataSet: TDataSet);
begin
  cdsDetail.DisableControls;
  try
    DBCtrlGrid1.RowCount := cdsDetail.RecordCount;
  finally
    cdsDetail.EnableControls;
  end;
end;

Answer 2

只需在表单上放置一个 TDBEdit，然后设置其 Datafield 属性和详细信息表的 Datasource 属性。