首先 - Artem 打败了我,但正确的代码是:
CREATE function MultiStringToTable (@InStr VARCHAR(255))
RETURNS @TempTab TABLE(id nvarchar(255) not null)
AS
BEGIN
-- Ensure input ends with comma
SET @InStr = REPLACE(@InStr + ',', ',,', ',');
DECLARE @SP INT;
DECLARE @VALEUR VARCHAR(1000);
WHILE PATINDEX('%,%', @INSTR ) <> 0
BEGIN
SET @SP = PATINDEX('%,%',@INSTR);
SET @VALEUR = LEFT(@INSTR , @SP - 1);
SET @INSTR = STUFF(@INSTR, 1, @SP, '');
INSERT INTO @TempTab(id) VALUES (@VALEUR);
END;
RETURN;
END;
GO
也就是说 - ^^^ 这将非常缓慢。对于您正在做的事情,您可以使用STRING_SPLIT。
DECLARE @instr VARCHAR(8000) = 'abc,,xxx,yyy,,z';
SELECT split.* FROM STRING_SPLIT(@instr,',') AS split WHERE split.[value] > '';
完成。更好的是,您可以有任意数量的逗号,它们将被视为一个。请注意以下更改:
DECLARE @instr VARCHAR(8000) = 'abc,,,,xxx,,yyy,,z,w,,,,sss,,';
这会返回:
value
----------
abc
xxx
yyy
z
w
sss
为了了解性能差异,让我们做一个快速测试。
PRINT CHAR(10)+'STRING_SPLIT'+CHAR(10)+REPLICATE('-',90);
GO
DECLARE @st DATETIME = GETDATE(), @x VARCHAR(8000);
SELECT @x = split.[value]
FROM #strings AS s
CROSS APPLY STRING_SPLIT(s.String,',') AS split
WHERE split.[value] > ''
PRINT DATEDIFF(MS,@st,GETDATE());
GO 3
PRINT CHAR(10)+'dbo.MultiStringToTable'+CHAR(10)+REPLICATE('-',90);
GO
DECLARE @st DATETIME = GETDATE(), @x VARCHAR(8000);
SELECT @x = split.id
FROM #strings AS s
CROSS APPLY dbo.MultiStringToTable(s.String) AS split
WHERE split.id > '';
PRINT DATEDIFF(MS,@st,GETDATE());
GO 3
STRING_SPLIT
--------------------------------------------------------------------------------------
Beginning execution loop
140
184
153
Batch execution completed 3 times.
dbo.MultiStringToTable
--------------------------------------------------------------------------------------
Beginning execution loop
14046
14174
14466
Batch execution completed 3 times.
STRING_SPLIT 大约快一百倍,而且启动的代码少得多。