返回连续日期的临时表

Question

我需要创建一个返回连续日期表的函数。我会传入一个最小和最大日期。

我希望它可以这样调用：

SELECT * FROM GetDates('01/01/2009', '12/31/2009')

我目前有一个执行此操作的存储过程，但要求发生了变化，现在我需要在联合中包含返回的数据：

 with mycte as
(
     select cast(@minDate as datetime) DateValue
     union all
     select DateValue + 1
     from    mycte   
     where   DateValue + 1 <= @maxDate
 )
 select DateValue
 from    mycte
option (maxrecursion 1000)

但是，问题是我需要将递归设置为大于 100。根据 Gail Erickson [MS] 在 eggheadcafe 上的帖子，目前不支持此功能。

如果不创建一个真正的（不是临时的）表，其中只有日期，有没有办法做到这一点？

我正在使用 SqlServer2005。

Answer 1

您最好的选择是实际拥有一个实际的日期表。即使在很长一段时间内也没有那么多，而且比从临时表或递归 ctes 即时实现它们要快得多。

Answer 2

如果您选择（或需要）使用临时表而不是永久表，则可以这样做：

CREATE FUNCTION dbo.DateList
 (
   @MinDate datetime
  ,@MaxDate datetime
 )
RETURNS TABLE
RETURN WITH
  Pass0 as (select 1 as C union all select 1), --2 rows
  Pass1 as (select 1 as C from Pass0 as A, Pass0 as B),--4 rows
  Pass2 as (select 1 as C from Pass1 as A, Pass1 as B),--16 rows
  Pass3 as (select 1 as C from Pass2 as A, Pass2 as B),--256 rows
  Pass4 as (select 1 as C from Pass3 as A, Pass3 as B),--65536 rows
  Tally as (select row_number() over(order by C) as Number from Pass4)
 select dateadd(dd, Number - 1, @MinDate) DateValue
 from Tally
 where Number < datediff(dd, @MindAte, @MaxDate) + 2

去

还有一个测试电话：

DECLARE
  @MinDate datetime
 ,@MaxDate datetime

SET @MinDate = 'Jan 1, 2009'
SET @MaxDate = 'Dec 31, 2009'

SELECT *
 from dbo.DateList(@MinDate, @MaxDate)

奇怪——这是今天第三篇涉及 Tally 表的 SO 帖子。一定是发生了一些奇怪的太阳黑子活动。以下是链接：

count number of rows that occur for each date in column date range.
What is the best way to create and populate a numbers table?

Answer 3

类似这样的：

CREATE FUNCTION GetDates(@StartDate DateTime, @EndDate DateTime) 

RETURNS @Dates Table ( aDate DateTime Primary Key Not Null)
AS
BEGIN
 Declare @ThisDate DateTime Set @ThisDate = @StartDate  
 While @ThisDate < @EndDate begin      
      Insert @Dates (aDate) Values(@THisDate)      
      Set @ThisDate = @ThisDate + 1  
 End
RETURN 
END
GO

确保@EndDate 在@startdate 之后...添加输入参数检查以确保，否则如果您向后传递日期，它可能会永远运行