FUNCTION 调用问题中的 PL/SQL 集合答案

【问题标题】：PL/SQL collection in FUNCTION call issueFUNCTION 调用问题中的 PL/SQL 集合
【发布时间】：2018-07-11 11:07:13
【问题描述】：

我有一个函数 MY_FUNC，它将 PL/SQL 集合作为参数。

但是，当我尝试编译具有在 INSERT 语句中调用 MY_FUNC 的过程 (MY_PROCEDURE) 的包时出现错误。这是过程和对函数的调用

    MY_PROCEDURE (var1 IN OUT VARCHAR2, in_table_list IN OUT bf_types.table_of_addresses_type) 

    IS

    BEGIN

    INSERT INTO my_tab
    SELECT col_A,
           col_B, 
           MY_FUNC(var1, in_table_list)
    FROM json_table (json_str etc etc)

    END my_procedure;
/

我收到以下错误：

541/3 PL/SQL：忽略 SQL 语句 561/3 PL/SQL：ORA-00904：“MY_FUNC”：无效标识符

561/3 PLS-00306：调用中的参数数量或类型错误 'MY_FUNC'

561/42 PLS-00382：表达式类型错误

这是 MY_FUNC 的代码，编译良好：

CREATE OR REPLACE FUNCTION my_func (in_marketid IN VARCHAR2, in_list_of_addresses IN bf_types.table_of_addresses_type) RETURN DATE
IS
cnt INTEGER;
BEGIN
cnt := TO_NUMBER(SUBSTR(in_marketid,1,1));
  RETURN(in_list_of_addresses(cnt).move_in_date);
END my_func;`

为了测试，我更改了 MY_FUNC 以删除 PL/SQL 集合参数并修改了我的调用。

即创建或替换函数 my_func (in_marketid IN VARCHAR2) 返回日期

代码编译，因此如果函数将 PL/SQL 表（集合）作为参数，则在 INSERT 语句中调用函数似乎存在问题。另外，请注意 MY_FUNC 已在包外声明。

如果有人能提供帮助，我将不胜感激。

【问题讨论】：

你可以在调用部分尝试使用 schema name.function_name
如果架构名称是 schema1 那么 schema1.MyFunc
或从插入语句中删除函数调用，并尝试在过程中正常调用该函数..并检查它是否正常工作。

标签： function plsql collections

【解决方案1】：

但是，当我尝试编译具有在 INSERT 语句中调用 MY_FUNC 的过程 (MY_PROCEDURE)。这是过程和对函数的调用

我试图模拟你的情况并准备了一些你可以参考的东西。请阅读我的内联 cmets。

--Created Object
CREATE OR REPLACE TYPE  table_of_addresses_type IS OBJECT
(
  move_in_date date
);
--table of your object
create or replace Type v_table_of_addresses_type is table of  table_of_addresses_type;
/
--Table for inserting the record
CREATE TABLE my_tab(col DATE);
/
--Function
CREATE OR REPLACE   FUNCTION my_func(
            in_marketid          IN VARCHAR2,
            in_list_of_addresses IN v_table_of_addresses_type)
        RETURN DATE
    IS
        cnt INTEGER;
    BEGIN
        cnt := TO_NUMBER(SUBSTR(in_marketid,1,1));
        RETURN(in_list_of_addresses(cnt).move_in_date);
    END my_func;
/
--Procedure
CREATE OR REPLACE PROCEDURE MY_PROCEDURE(
        var1          IN OUT VARCHAR2,
        in_table_list IN OUT v_table_of_addresses_type)
IS
BEGIN
        INSERT INTO my_tab
        SELECT MY_FUNC(var1, in_table_list) FROM dual;
    COMMIT;
END my_procedure;
/

--Calling / Exection:

DECLARE
    x v_table_of_addresses_type :=v_table_of_addresses_type();
    v_dt DATE;
    var1 VARCHAR2(10);
BEGIN
    x.EXTEND(3);
  --Populating the collection manually. You can populate it via a query as well
    x(1) := table_of_addresses_type(to_date('2017-05-21','YYYY-MM-DD'));
    x(2) := table_of_addresses_type(to_date('2017-05-22','YYYY-MM-DD'));
    x(3) := table_of_addresses_type(to_date('2017-05-23','YYYY-MM-DD'));
    --testing function call
    v_dt := MY_FUNC('111',x);
    dbms_output.put_line (v_dt);

    var1:= '111';
  --Calling Procedure. have to pass the var1 since its decalre as INOUT paramater in your procedure.
    MY_PROCEDURE(var1,x);

END;
/
--testing records from the table
Select * from my_tab

PS：您可以将过程和函数包装在我的回答中没有做的包中。

【讨论】：