如何运行返回多个值的Oracle函数

Question

我的测试函数是这个

CREATE OR REPLACE FUNCTION MULTI_VAL
(MYNAME OUT EMP2017.ENAME%TYPE)
RETURN NUMBER AS
  MYSAL EMP2017.SAL%TYPE;
BEGIN
  SELECT SAL, ENAME INTO MYSAL, MYNAME FROM EMP2017 ;
  RETURN MYSAL;
END;
/

当我像运行它时

variable mynm varchar2(20)

SELECT MULTI_VAL(:mynm) FROM dual;

它给出了这个错误

第 1 行出现错误：
ORA-06553: PLS-561: 参数 'MYNAME' 值的字符集不匹配

Answer 1

您现在得到的错误表明数据类型不匹配。

但是，您的代码存在一个根本问题。我们不能在 SQL 中使用具有 OUT 参数的函数。因此，一旦您修复了数据类型问题，您将收到此错误：ORA-06572: Function MULTI_VAL has out arguments。

你可以这样运行它：

declare
    n varchar2(20);
    x number;
begin
    x := multi_val(n);
end;
/

通常，带有 OUT 参数的函数被认为是不好的做法。语法允许它们，但用法很难理解。最好使用带有两个 OUT 参数的过程（因为无论如何我们只能在 PL/SQL 中调用该程序）或者让函数返回用户定义的类型。

Answer 2

CREATE TABLE EMP2017(ENAME VARCHAR2(10),SAL NUMBER);

INSERT INTO EMP2017 VALUES ('SMITH',5000);
INSERT INTO EMP2017 VALUES ('JOHNS',1000);

COMMIT;

CREATE  TYPE RET_MULT AS OBJECT 
(ENAME     VARCHAR2(10),SAL NUMBER); 

CREATE TYPE T_RET_MULT AS TABLE OF RET_MULT;

CREATE OR REPLACE FUNCTION MULTI_VAL RETURN T_RET_MULT PIPELINED IS 
 MYSAL  RET_MULT;
BEGIN
FOR I IN(SELECT SAL, ENAME FROM EMP2017) LOOP
  MYSAL := RET_MULT(I.ENAME,I.SAL);
  PIPE ROW(MYSAL);
END LOOP ;
RETURN ;
END;

SELECT * FROM TABLE(MULTI_VAL());

Answer 3

我认为这个问题可以不使用管道函数来解决。像这样。除功能外，所有预先需要的数据都与@Sedat.Turan 所述相同。抱歉复制/过去。

CREATE TABLE EMP2017(ENAME VARCHAR2(10),SAL NUMBER);

INSERT INTO EMP2017 VALUES ('SMITH',5000);
INSERT INTO EMP2017 VALUES ('JOHNS',1000);

COMMIT;

CREATE  TYPE RET_MULT AS OBJECT 
(ENAME     VARCHAR2(10),SAL NUMBER); 

CREATE TYPE T_RET_MULT AS TABLE OF RET_MULT;
    create or replace function MULTI_VAL return T_RET_MULT is
       RET_SET T_RET_MULT;
    begin

       select RET_MULT(ENAME, SAL) bulk collect into RET_SET from EMP2017;

       return RET_SET;
    end;