如何将此 pl/sql 更改为函数？

Question

我正在完成一本小册子中的练习，因为我刚刚在 Oracle 中学习 PL/SQL，它希望我把它变成一个函数，我不知道我怎么能，因为它不是一个存储过程，至少我不知道'认为它是，并且没有要进行的计算......有什么想法我应该做什么？

DECLARE
my_stdate LEASE.STDATE%TYPE;
my_enddate LEASE.ENDDATE%TYPE;
my_property_no LEASE.PROPERTY_NO%TYPE;

BEGIN
SELECT stdate, enddate, property_no
INTO my_stdate, my_enddate, my_property_no
FROM lease
WHERE lease_no = '&enter_lease_no';
DBMS_OUTPUT.PUT_LINE('Property '||my_property_no||' was leased from '||my_stdate||' and '||my_enddate);
END;
/

Answer 1

替换变量 &enter_lease_no 是输入，DBMS_OUTPUT.PUT_LINE(...) 是 PL/SQL 匿名块的输出。

要使其成为函数，请将租约号作为参数（而不是替换变量）传入，并返回要输出的字符串值。

CREATE FUNCTION test_function(
  enter_lease_no IN LEASE.LEASE_NO%TYPE
) RETURN VARCHAR2
IS
  my_stdate      LEASE.STDATE%TYPE;
  my_enddate     LEASE.ENDDATE%TYPE;
  my_property_no LEASE.PROPERTY_NO%TYPE;
BEGIN
  SELECT stdate, enddate, property_no
  INTO my_stdate, my_enddate, my_property_no
  FROM lease
  WHERE lease_no = enter_lease_no;

  RETURN 'Property '||my_property_no||' was leased from '||my_stdate||' and '||my_enddate;
END;
/

然后可以使用：

BEGIN
  DBMS_OUTPUT.PUT_LINE( test_function( '&enter_lease_no' ) );
END;
/