【问题标题】:PLS-00540: Object not supported in this context while trying to compile package specificationPLS-00540:尝试编译包规范时在此上下文中不支持对象
【发布时间】:2015-10-14 19:47:10
【问题描述】:

我正在尝试编译一个包规范。我想包含一些类型定义并声明一个函数:

TYPE col_type AS OBJECT (
col_name VARCHAR2(50)
);

TYPE col_sub_type
IS TABLE OF
col_type;

FUNCTION get_col_tab RETURN col_sub_type;

最后,get_col_tab 函数:

FUNCTION get_col_tab RETURN col_sub_type AS
l_type  col_sub_type := col_sub_type();
BEGIN
FOR i IN (SELECT DISTINCT TABLE_NAME t_name FROM ALL_TAB_COLUMNS WHERE TABLE_NAME = 'TABLE_1') LOOP
l_type.extend;
l_type(l_type.last) := col_type(i.t_name);
END LOOP;
RETURN l_type;
END;

但是在编译包规范时出现以下错误:

PLS-00540:此上下文中不支持对象

据我了解,我不能在包规范中使用类型 OBJECT。有解决方法或其他方法吗?

提前致谢。

【问题讨论】:

    标签: oracle plsql


    【解决方案1】:

    在 PL/SQL 中,您必须使用 record 而不是 object。

    TYPE col_type IS RECORD (
    col_name VARCHAR2(50)
    );
    
    TYPE col_sub_type
    IS TABLE OF
    col_type;
    
    FUNCTION get_col_tab RETURN col_sub_type;
    

    虽然存在一些功能差异,但如果您只是想创建一组列定义,它们实际上是相同的。


    其中一个区别是record 类型不支持构造函数(隐式或显式)。这意味着您需要单独分配每个字段:

    l_type(l_type.last).col_name := i.t_name;
    

    另一种方法是使用bulk collect:

    SELECT DISTINCT table_name t_name
    BULK   COLLECT INTO l_type
    FROM   all_tab_columns
    WHERE  table_name = 'TABLE_1';
    

    【讨论】:

    • 包规范现在编译得很好,谢谢,但是当我尝试编译包主体时,我得到以下信息:PLS-00222: no function with name 'COL_TYPE' exists in this scope
    • 我通过添加整个 get_col_tab 函数扩展了我的问题。
    【解决方案2】:

    为什么要使用对象?

    简单地做

    TYPE col_sub_type IS TABLE OF VARCHAR2(50);
    

    然后

    FUNCTION get_col_tab RETURN col_sub_type AS
    l_type  col_sub_type;
    BEGIN
    
       SELECT DISTINCT TABLE_NAME 
       BULK COLLECT INTO l_type
       FROM ALL_TAB_COLUMNS 
       WHERE TABLE_NAME = 'TABLE_1';
    
       RETURN l_type;
    END;
    

    【讨论】:

    • 感谢您的建议,但仍然存在新问题。 Function get_col_tab cannot be used in SQL...
    • 你还必须在包中声明你的函数,而不仅仅是在包体中。
    猜你喜欢
    • 1970-01-01
    • 1970-01-01
    • 2011-06-24
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2019-11-28
    • 2019-08-27
    相关资源
    最近更新 更多