为什么我的 where 语句没有返回结果？

Question

我正在使用 Excel VBA 从 Access 数据库中提取数据。我的“Select”和“From”语句工作正常。当我添加“Where”语句时，我没有得到任何结果。你能帮忙吗？！

Dim SDATE As String
Dim EDATE As String
Dim SQLstring As String

SDATE = Application.InputBox("Beginning Date", "Date 1", Format(Date - 31, "MM-DD-YY"))
EDATE = Application.InputBox("Ending Date", "Date 2", Format(Date, "MM-DD-YY"))

SQLstring = "SELECT tblitemhistory.HistDate, tblstockitems.MasterPNo, tblstockitems.ItemDescription, tblitemhistory.HistType, tblitemhistory.HistText, tblitemhistory.HistQty " & _
            "FROM tblitemhistory INNER JOIN tblstockitems ON tblitemhistory.StockID = tblstockitems.ItemID" & _
            "where (((tblitemhistory.HistDate)  between #" & [SDATE] & "# AND #" & [EDATE] & "#"""

getSQLString = SQLstring

我希望在用户输入的两个日期之间提取记录。运行代码时我没有收到任何错误，但我也没有得到任何结果。

Answer 1

尝试从 [SDATE] 和 [EDATE] 中删除括号。这是 SQL 语法，而不是 VBA 语法。

您可能会考虑将格式修改为 mm/dd/yyyy，日期的区域解释可能会让您头疼。

看这个：

https://bytes.com/topic/access/insights/575420-literal-datetimes-their-delimiters

**编辑**

我刚刚意识到您并没有终止所有这些括号：(((tblitemhistory.HistDate)。你不需要它们中的任何一个。此外，末尾有 3 个引号会在查询末尾添加一个您可能不想要的引号，请尝试 "where tblitemhistory.HistDate BETWEEN #" & SDATE & "# AND #" & EDATE & "#"

Answer 2

可能您所在的地区将日期作为日期优先而不是月份优先。因此，无论输入什么日期范围，根据该部分不存在任何数据，因为您没有收到任何错误。

因此，考虑两个调整：

1. 删除任何格式并让用户在他们所在的任何区域输入日期，并根据其 CPU 的默认设置调整日期。

2. 使用 MS Access'QueryDefs 的参数化，而不是 VBA 中的 SQL 连接，如下所示，使用 DAO 连接。

Sub RunQuery()
    Dim SDATE As Date, EDATE As Date
    Dim SQLstring As String
    Dim conn As Object, db As Object, qdef As Object

    SDATE = Application.InputBox("Beginning Date", "Date 1", Date - 31)   ' REMOVE Format()
    EDATE = Application.InputBox("Ending Date", "Date 2", Date)           ' REMOVE Format()

    Set conn = CreateObject("DAO.DBEngine.120")
    Set db = conn.OpenDatabase("C:\Path\To\Database.accdb")

    ' PREPARED STATEMENT (NO DATA) - CAN BE SAVED IN MS ACCESS AS QUERY OBJECT
    SQLstring = "PARAMETERS [Prm_SDATE] Date, [Prm_EDATE] Date;" & _
                "SELECT i.HistDate, s.MasterPNo, s.ItemDescription," & _
                "       i.HistType, i.HistText, i.HistQty " & _
                "FROM tblitemhistory i " & _
                "INNER JOIN tblstockitems s ON i.StockID = s.ItemID" & _
                "WHERE i.HistDate BETWEEN [Prm_SDATE] AND [Prm_EDATE];"

    ' BIND PARAMETERS
    Set qdef = db.CreateQueryDef("", SQLstring)
    qdef![Prm_SDATE] = SDATE
    qdef![Prm_EDATE] = EDATE

    ' OPEN RECORDSET
    Set rst = qdef.OpenRecordset

    ' DUMP OUTPUT TO EXCEL SHEET
    Worksheets("Sheet1").Range("A1").CopyFromRecordset rst

    rst.Close: db.Close        
    Set qdef = Nothing: Set db = Nothing: Set conn = Nothing
End Sub