VLookup 在另一个工作簿上

Question

尝试创建一个宏，该宏将从单元格 A7、A8、A9 等输入（13 位数字）直到到达空白单元格，然后针对另一个工作簿运行 vlookup。

但是，我只是收到 #N/A 错误，我不知道为什么。

我当前的代码：

Sub getData()

Application.EnableEvents = False
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Application.Calculation = xlManual

Dim wb As Workbook, src As Workbook
Dim srcRange As Range
Dim InputString
Dim OutputString
Dim i As Long

Set wb = ActiveWorkbook
Set src = Workbooks.Open("D:\Files\test1.csv", True, True)
Set srcRange = src.Sheets(1).Range("A1:H1").End(xlDown)

i = 7

Do While wb.ActiveSheet.Cells(i, 1) <> ""

    InputString = wb.Worksheets("Sheet 1").Cells(i, 1)

    OutputString = Application.VLookup(InputString, srcRange, 3, False)

    wb.Worksheets("Sheet 1").Cells(i, 2) = OutputString

    i = i + 1

Loop


src.Close (False)

Application.EnableEvents = True
Application.ScreenUpdating = True
Application.DisplayAlerts = True
Application.Calculation = xlAutomatic

End Sub

我认为值得注意的是，我正在查找的引用（“InputString”）在“src”文件中定义为自定义格式 #0。不知道是不是太重要了，应该还是整数吧？

此外，“OutputString”可以是数字或文本，这就是为什么我故意让它未定义的原因。我尝试将其定义为“Variant”、“String”和“Integer”，但这并没有真正改变任何东西。

谢谢。

Answer 1

Set srcRange = src.Sheets(1).Range("A1:H1").End(xlDown)

这将在A 列上为您提供一个单个单元格的范围，即A20。 在单个单元格上执行VLookup 毫无意义。

你的意思可能是这样的：

With Sheets(1)
    Set srcRange = .Range("A1:H" & .Range("A1").End(xlDown).Row)
End With

这将设置为A1:H20。

Answer 2

首先您应该更改您的 src 范围，该范围实际上设置为仅抓取底行，而不是从上到下的范围。试试

Set wb = ActiveWorkbook
Set src = Workbooks.Open(""D:\Files\test1.csv", True, True)
With src.Sheets(1)
    Set srcRange = .Range(.Range("A1"), .Range("H1").End(xlDown))
End With

其次，我认为 CSV 文件不支持 13 位数字，但文本除外。 VLOOKUP 对 text vs general vs number 非常敏感，所以如果新的 src 范围没有帮助，请先尝试使用 CStr() 转换输入字符串。

祝你好运！