如何在 Delphi 中使用 TXMLDocument 将 Ansi 转换为 UTF 8

Question

可以在 Delphi 6 中将 XML 转换为 UTF-8 编码吗？
目前这就是我正在做的事情：

• 用 AnsiString 填充 TXMLDocument
• 最后使用WideStringVariable = AnsiToUtf8(Doc.XML.Text);将数据转换为UTF-8
• 使用TFileStream 将WideStringVariable 的值保存到文件中，并在文件开头添加BOM for UTF8。

代码：

Procedure SaveAsUTF8( const Name:String; Data: TStrings );

const
  cUTF8 = $BFBBEF;
var
  W_TXT: WideString;
  fs: TFileStream;
  wBOM: Integer;
begin
  if TRIM(Data.Text) <> '' then begin    
    W_TXT:= AnsiToUTF8(Data.Text);
    fs:= Tfilestream.create( Name, fmCreate );
    try
      wBOM := cUTF8;
      fs.WriteBUffer( wBOM, sizeof(wBOM)-1);
      fs.WriteBuffer( W_TXT[1], Length(W_TXT)*Sizeof( W_TXT[1] ));
    finally
      fs.free
    end;
  end;
end;

如果我在 Notepad++ 或其他检测编码的编辑器中打开文件，它会显示带有 BOM 的 UTF-8。但是，它似乎没有正确编码文本。

出了什么问题，我该如何解决？

更新：XML 属性：

XMLDoc.Version := '1.0';
XMLDoc.Encoding := 'UTF-8';
XMLDoc.StandAlone := 'yes';

Answer 1

您可以使用标准SaveToFile 方法在TXMLDocument 变量上保存文件：http://docs.embarcadero.com/products/rad_studio/delphiAndcpp2009/HelpUpdate2/EN/html/delphivclwin32/XMLDoc_TXMLDocument_SaveToFile.html

文件是否为 UTF8，您必须使用本地工具（如前面提到的 Notepad++ 或 Hex Editor 或其他任何工具）进行检查。

---

如果你坚持使用中间字符串和文件流，你应该使用适当的变量。 AnsiToUTF8 返回 UTF8String 类型，这就是要使用的内容。 编译 `WideStringVar := AnsiStringSource' 会发出编译器警告和

这是一个正确的警告。谷歌搜索“Delphi WideString” - 或阅读有关主题的 Delphi 手册 - 表明 WideString aka Microsoft OLE BSTR 以 UTF-16 格式保存数据。 http://delphi.about.com/od/beginners/l/aa071800a.htm 因此赋值UTF16 string <= 8-bit source必然会转换数据，因此转储WideString数据不能转储UTF-8定义WideString的文本

Procedure SaveAsUTF8( const Name:String; Data: TStrings );
const
  cUTF8: array [1..3] of byte = ($EF,$BB,$BF)
var
  W_TXT: UTF8String;
  fs: TFileStream;
  Trimmed: AnsiString;
begin
  Trimmed := TRIM(Data.Text);
  if Trimmed <> '' then begin    
    W_TXT:= AnsiToUTF8(Trimmed);
    fs:= TFileStream.Create( Name, fmCreate );
    try
      fs.WriteBuffer( cUTF8[1], sizeof(cUTF8) );
      fs.WriteBuffer( W_TXT[1], Length(W_TXT)*Sizeof( W_TXT[1] ));
    finally
      fs.free
    end;
  end;
end;

顺便说一句，如果源数据为空，您的这段代码甚至不会创建空文件。它看起来相当可疑，尽管由您来决定这是否是您程序的其余部分的错误。

---

将接收到的文件或流正确“上传”到网络是另一个问题（将作为一个单独的问题放在像 SO 这样的问答网站上），与测试与 HTTP 的一致性有关。作为前言，你可以在WWW server reports error after POST Request by Internet Direct components in Delphi阅读一些提示

Answer 2

为了在文档中获得正确的编码，您应该使用 XML 文档中的 Encoding 属性进行设置，如下所示：

myXMLDocument.Encoding := 'UTF-8';

我希望这会有所帮助。

Answer 3

你只需要调用文档的SaveToFile方法：

XMLDoc.SaveToFile(FileName);

由于您已经指定了编码，组件将使用该编码。

这不包括 BOM，但这通常是您想要的 XML 文件。文件内容将指定编码。

---

关于你的SaveAsUTF8 方法，不需要，但很容易修复。这可能对你有启发。

问题是当您分配给WideString 变量时，您正在转换为UTF-16。您应该将 UTF-8 文本放入 AnsiString 变量中。将您命名为W_TXT 的变量类型更改为AnsiString 就足够了。

函数可能如下所示：

Procedure SaveAsUTF8(const Name: string; Data: TStrings);
const    
  UTF8BOM: array [0..2] of AnsiChar = #$EF#$BB#$BF;
var
  utf8: AnsiString;
  fs: TFileStream;
begin
  utf8 := AnsiToUTF8(Data.Text);
  fs:= Tfilestream.create(Name, fmCreate);
  try
    fs.WriteBuffer(UTF8BOM, SizeOf(UTF8BOM));
    fs.WriteBuffer(Pointer(utf8)^, Length(utf8));
  finally
    fs.free;
  end;
end;

Answer 4

另一种解决方案：

procedure SaveAsUTF8(const Name: string; Data: TStrings);
var
  fs: TFileStream;
  vStreamWriter: TStreamWriter;
begin
  fs := TFileStream.Create(Name, fmCreate);
  try
    vStreamWriter := TStreamWriter.Create(fs, TEncoding.UTF8);
    try
      vStreamWriter.Write(Data.Text);
    finally
      vStreamWriter.Free;
    end;
  finally
    fs.free;
  end;
end;