TSQL Geography STGeomFromText 显示错误的结果

Question

我正在尝试编写一个代码来告诉我点是否在多边形内

DECLARE @Latitude varchar(20) = '41.694110'
DECLARE @Longitude varchar(20) = '44.833680'
DECLARE @g geography;
DECLARE @p geography;

DECLARE @PolygonString varchar(500) = 'POLYGON((41.711921 44.658505, 41.851703 44.773175, 41.763158 44.972302, 41.654421 44.843083, 41.711921 44.658505))'

SET @g = geography::STGeomFromText(@PolygonString, 4326);
SET @p = geography::Point(@Latitude, @Longitude, 4326)

SELECT @g.STIntersects(@p)

它总是返回 0。这是场景的可视化表示。

http://sbtutor.com/

知道我的代码有什么问题吗？

谢谢。

Answer 1

mdisbio 的回答让我想到了参数的顺序，所以一旦我反转了每个参数的 long/lat 顺序以遵守左手规则，我不得不重新排序这些点，最后得出的结果是相交的。

DECLARE @Latitude varchar(20) = '41.694110'
DECLARE @Longitude varchar(20) = '44.833680'
DECLARE @g geography;
DECLARE @p geography;

DECLARE @PolygonString varchar(500) = 'POLYGON((44.658505 41.711921, 44.843083 41.654421, 44.972302 41.763158, 44.773175 41.851703, 44.658505 41.711921))'

SET @g = geography::STGeomFromText(@PolygonString, 4326);
SET @p = geography::Point(@Latitude, @Longitude, 4326)

SELECT @g.STIntersects(@p)
--1

所以对于Points，排序是纬度/经度，但似乎对于多边形，排序被解释为经度/纬度。记住这一点，这应该是轻而易举的事。

Answer 2

我不是地理空间类型方面的专家，但可以给你一些想法。 对于 WKT 字符串（用于制作多边形的字符串），对需要是 long/lat 而不是 lat/long。

也就是说，我仍然无法将您的多边形识别为有效的地理，因为我没有应用 Jaaz 稍后指出的逆时针规则。所以我使用了没有那么严格的几何类型，它工作正常。

使用几何作为多边形，POINT 也必须是几何。在这种情况下，geometry::POINT() 需要 X,Y 坐标 (lng/lat)，而不是与 geography 类型一起使用的 lat/lng 对。

所以，这将在相交处产生 true：

DECLARE @Latitude float = 41.694110
DECLARE @Longitude float = 44.833680
DECLARE @g geometry = geometry::Point(@Longitude, @Latitude, 4326)
DECLARE @p geometry = geometry::STPolyFromText('POLYGON((44.658505 41.711921, 44.773175 41.851703, 44.972302 41.763158, 44.843083 41.654421, 44.658505 41.711921))', 4326);
SELECT @g.STIntersects(@p)