在 Cython 中包装自定义类型 C++ 指针答案

【问题标题】：Wrapping custom type C++ pointer in Cython在 Cython 中包装自定义类型 C++ 指针
【发布时间】：2015-02-27 17:32:45
【问题描述】：

使用 Cython 包装自定义类型 C++ 指针的最佳方法是什么？

例如：

import numpy as np
cimport numpy as np

cdef extern from "A_c.h"
    cdef cppclass A:
       A();
       void Foo(A* vec);

cdef class pyA:
    cdef A *thisptr
    def ___cinit___(self):
        self.thisptr = new A()
    def __dealloc___(self):
        del self.thisptr

我应该如何使用 cython 来包装 Foo？我尝试了以下方法，但我从 Buffer.py 中得到了断言错误，或者 A 不是 memoryview 切片的基本类型的错误

def Foo(self, np.ndarray[A, mode='c'] vec)
def Foo(self, A[::1] vec)

【问题讨论】：

A* vec 是指向单个对象的指针还是A 类型的对象向量？我想知道“vec”这个名字和你对 numpy/memory 视图的使用。
在这种情况下，它是指向单个对象A的指针，不幸的是vec被选为占位符名称

标签： python c++ pointers numpy cython

【解决方案1】：

基本上每次你想传递A 类型的对象或指向它的指针时，你都应该使用pyA 类型的Python 对象——这实际上与指针非常相似，除了它有引用之外计数，所以它就像 C++11 中的 shared_ptr，只是它只知道 Python（或 Cython）中的引用。 [编辑] 请注意 Python 对象可以是 None，您可以使用 not None 子句轻松防止这种情况。

当然，这不仅适用于参数，也适用于返回类型，因此每个返回指向A 类型对象的指针的方法都应该返回pyA-object。为此，您可以创建一个 cdef 方法名称，例如 setThis，它允许设置包含的指针。

如上所述，如果您以这种方式包装指针，则内存管理在 Python 中完成，因此一方面您需要确保如果您的 C++ 对象持有指向 Python 对象不会被删除的对象的指针（例如，通过在 Cython 中存储对 Python 对象的引用），另一方面，如果对象仍包含在 Python 对象中，则不应从 C++ 中删除对象。如果您已经在 C++ 中进行了某种内存管理，您还可以在 C++ 对象是否应该被删除时向您的 Cython 对象添加标志。

我对您的示例进行了一些扩展，以说明如何在 Cython 中实现这一点：

cdef extern from "A_c.h":
    cdef cppclass A:
        A()
        void Foo(A* vec)
        A* Bar()

    cdef cppclass AContainer:
        AContainer(A* element)

cdef class pyA:
    cdef A *thisptr
    def ___cinit___(self):
        self.thisptr = new A()

    def __dealloc___(self):
        del self.thisptr

    cdef setThis(self, A* other):
        del self.thisptr
        self.thisptr = other
        return self

    def Foo(self, pyA vec not None): # Prevent passing None
        self.thisptr.Foo(vec.thisptr)

    def Bar(self):
        return pyA().setThis(self.thisptr.Bar())

cdef class pyAContainer:
    cdef AContainer *thisptr
    cdef pyA element

    def __cinit__(self, pyA element not None):
        self.element = element # store reference in order to prevent deletion
        self.thisptr = new AContainer(element.thisptr)

    def __dealloc__(self):
        del self.thisptr # this should not delete the element
        # reference counting for the element is done automatically

【讨论】：