CMake：将第三方库链接到项目库

Question

我目前正在开发一个使用 CMake 作为其构建系统的 C++ 项目。

这些项目由几个输出可执行文件组成，每个可执行文件的自定义代码相对较少，但利用了一些常用库：

programX
|
├── CMakeLists.txt (this contains the main executable targets)
|
├── Engine
│   ├── ...
│   ├── CMakeLists.txt
|
├── Utils
│   ├── third_party (this is what I added)
│   │   └── backward-cpp
│   |       └ CMakeLists.txt
│   ├── ...
│   └── CMakeLists.txt
|
└── etc.

项目的主要功能包含在Engine 库中，该库使用target_link_libraries(programX Engine) 等静态链接到主要可执行文件。许多实用程序也包含在单独的Utils 库中。

我已将 CMake 依赖项添加到这些项目库之一（它是 backward-cpp stacktrace 美化器）。该项目也是使用 CMake 构建的。

为了模块化，我已将backward-cpp 项目作为依赖项添加到唯一实际使用它的项目库Utils。我这样做是为了不使用仅与项目的一小部分相关的指令“污染”主 CMakeLists.txt 文件。

我的Utils/CMakeLists.txt 因此看起来像这样：

SET(UTILS_HEADERS ...)
set(UTILS_OBJECTS Dummy.cpp ${UTILS_HEADERS})

# This is the new dependency!
add_subdirectory(third_party/backward-cpp)

SOURCE_GROUP("" FILES ${UTILS_HEADERS})

# 'BACKWARD_ENABLE' and 'add_backward' are needed for linking.
add_library(Utils ${UTILS_OBJECTS} ${BACKWARD_ENABLE})
add_backward(Utils)

但是，这样做不起作用，并且项目最终无法链接（未找到 backward-cpp 库中的符号），除非我将输出的可执行文件链接到第三方直接库，在根 CMakeLists.txt 文件 (add_backward(MainExecutableA-Z)) 中。

我知道无法将静态库链接到其他静态库，但我想知道是否有一种很好的方法可以使用 CMake 实现静态库及其依赖项的模块化。

（或者，我总是可以将所有内容直接链接到主要目标，因为这总是有效的。）

更新（2017 年 5 月 22 日）

我现在已经设法让一切正常，backwards-cpp 100% 受到“最窄”CMakeLists.txt 文件的控制，这要感谢我得到的有用答案。这是我最终得到的Utils/CMakeLists.txt 文件（删除了不相关的部分）：

SET(UTILS_HEADERS ...)   
SET(UTILS_SOURCES ...)


# If enabled, enables sensible stack traces on Linux, complete with corresponding source
# code, where available. CUDA errors also produce complete stack traces when this is on.
# If disabled, the error messages degrade gracefully to file/line information.
OPTION(WITH_BACKWARDS_CPP "Build with backwards-cpp stack trace dumping library? (Linux-only)" TRUE)
message(STATUS "backwards-cpp-enhanced stack traces? " ${WITH_BACKWARDS_CPP})

if(WITH_BACKWARDS_CPP)
  # Support 'backward-cpp,' a lean stacktrace printing library for Linux.
  add_definitions(-DWITH_BACKWARDS_CPP)
  add_subdirectory(third_party/backward-cpp)
endif()

SOURCE_GROUP("" FILES ${UTILS_HEADERS} ${UTILS_SOURCES})
add_library(Utils ${UTILS_HEADERS} ${UTILS_SOURCES})

# ...unrelated CUDA stuff...

if(WITH_BACKWARDS_CPP)
  # Link agains libbfd to ensure backward-cpp can extract additional information from the binary,
  # such as source code mappings. The '-lbfd' dependency is optional, and if it is disabled, the
  # stack traces will still work, but won't show unmangled symbol names or source code snippets.
  # You may need to set BACKWARD_USE_BFD to 0 in its `hpp` and `cpp` files to avoid linker errors.
  target_link_libraries(Utils PUBLIC -lbfd)
  target_link_libraries(Utils PUBLIC backward)
endif()

Answer 1

在查看BackwardConfig.cmake 并阅读项目的README 后，我得出结论，将可执行文件与Backward-cpp 链接的最简单方法是使用add_backward(target) 宏正如你在问题中提到的那样。

README 中的 Modifying CMAKE_MODULE_PATH 副标题下描述的其他选项也可以工作，但我没有测试。 Config 模式下的find_package 将搜索名为<name>Config.cmake 的文件，在这种情况下为BackwardConfig.cmake，因此您不必编写任何额外的CMake 模块，例如FindBackward.cmake。作为尝试，我会执行以下操作：

set(UTILS_HEADERS ...)
set(UTILS_OBJECTS Dummy.cpp ${UTILS_HEADERS})

source_group("" FILES ${UTILS_HEADERS})
add_library(Utils ${UTILS_OBJECTS})

list(APPEND CMAKE_MODULE_PATH /path/to/backward-cpp)
find_package(Backward)

target_link_libraries(Utils PUBLIC Backward::Backward)

Answer 2

阅读README of backward-cpp后，我会尝试以下（仅最后两行更改）：

SET(UTILS_HEADERS ...)
set(UTILS_OBJECTS Dummy.cpp ${UTILS_HEADERS})

# This is the new dependency!
add_subdirectory(third_party/backward-cpp)

SOURCE_GROUP("" FILES ${UTILS_HEADERS})

add_library(Utils ${UTILS_OBJECTS})
target_link_libraries(Utils PUBLIC backward)

请注意，当您将其他目标链接到 Utils 时，最后一条语句中的 PUBLIC 负责设置包含目录和链接库。