如何通过 Winsock 从外部设备检索数据到 Microsoft Visual Basic (VB6)

Question

我需要创建一个应用程序，该应用程序需要通过 telnet 连接将数据从外部终端预订设备检索到我的应用程序，并将其显示在 txtOutput 文本框上。

我是 VB 的新手，花了一些时间学习该语言的基础知识。

首先，我创建了一个标准 EXE 项目并将 Winsock 控件添加到表单中。 我也向我想要连接的 IP 地址发出了 ping 请求，它可以正常工作。

然后我想向外部设备发送命令。我希望预订终端向我提供对 txtOutput 的反馈以供我阅读。

我建立了连接，据我所知，我确实将消息发送到终端。但我没有得到任何回应！在我的 txtOutput 上看不到任何内容。

怎么可能？

这是我的代码：

Dim IPAddress As String
Dim PortNum As Integer

Private Sub cmdConnect_Click()    
    Winsock.Close
    Winsock.RemoteHost = txtIpaddress.Text
    IPAddress = Winsock.RemoteHost
    PortNum = CStr(txtPortnr.Text)
    If (Val(PortNum) > 65535) Then
        Winsock.RemotePort = (Val(PortNum) - 65535)
        PortNum = Winsock.RemotePort
    Else
        Winsock.RemotePort = Val(PortNum)
        PortNum = Winsock.RemotePort
    End If

    Winsock.Connect

    Module1.send_to_buffer ("Attempting connection to: " & IPAddress & ":" & CStr(PortNum))

    Call wsock_status
    End Sub

Private Sub Winsock_Connect()
    Module1.send_to_buffer ("Succeeded connection to: " & IPAddress & ":" & CStr(PortNum))
    txtSend.SetFocus
End Sub

Private Sub cmdSend_Click()
Dim strSData As String
Dim message_to_send As String
    If (Winsock.State = 0) Then
        Module1.send_to_buffer ("You need to connect first!")
        txtSend.Text = ""
    Else
        strSData = txtSend.Text
        Winsock.SendData strSData & vbCrLf
        message_to_send = txtSend.Text
        If (message_to_send <> "") Then
            Winsock.SendData message_to_send & vbCrLf
            Module1.send_to_buffer_norm (txtSend.Text)
            txtSend.Text = ""
            txtSend.SetFocus
        Else
            Module1.send_to_buffer ("Nothing to send!")
            txtSend.Text = ""
            txtSend.SetFocus
        End If
    End If
End Sub

Private Sub terminalConnector_DataArrival(ByVal bytesTotal As Long)
Dim strData As String
    Winsock.GetData strData

    If (Len(txtOutput.Text) = 0) Then
        txtOutput.Text = strData & vbCrLf
    Else
        txtOutput.Text = txtOutput.Text & strData & vbCrLf
    End If
    End Sub

Private Sub cmdDisconnect_Click()
Dim Counter As Long
    If (Winsock.State <> 0) Then
        Winsock.Close
        Call wsock_status
        Module1.send_to_buffer ("Connection to " & IPAddress & ":" & CStr(PortNum) & " closed.")
    End If
End Sub

Private Sub Winsock_Close()
    Module1.send_to_buffer ("Disconnected from: " & IPAddress & ":" & CStr(PortNum))
    Winsock.Close
End Sub

和Module1代码：

Public Function send_to_buffer(text_to_display As String)
    If (Len(terminalConnector.txtOutput.Text) = 0) Then
        terminalConnector.txtOutput.Text = "*** " & text_to_display
    Else
        terminalConnector.txtOutput.Text = terminalConnector.txtOutput.Text & vbCrLf & "*** " & text_to_display & vbCrLf & vbCrLf
    End If
End Function

Public Function send_to_buffer_norm(text_to_input As String)
    If (Len(terminalConnector.txtOutput.Text) = 0) Then
        terminalConnector.txtOutput.Text = "> " & text_to_input & vbCrLf
    Else
        terminalConnector.txtOutput.Text = terminalConnector.txtOutput.Text & "> " & text_to_input & vbCrLf
    End If
End Function

提前致谢

Answer 1

DataArrival 事件命名错误：

在你的代码中是：

Private Sub terminalConnector_DataArrival(ByVal bytesTotal As Long)

但它应该是您的 winsock 控件的名称：

Private Sub Winsock_DataArrival(ByVal bytesTotal As Long)

您始终可以在 IDE 中的代码窗口上方左侧的组合框中选择控件名称，然后在 IDE 中的代码窗口上方的右侧组合框中选择事件名称，这将放置事件代码的轮廓在您的代码窗口中。

或者您可以在 IDE 中双击设计窗口上的控件，这将带您进入代码窗口并将事件代码的轮廓放在您的代码窗口中.. 然后您可以选择您想要的事件代码窗口右上方的组合框

附注：Winsock 可能不是winsock 控件的最佳名称，最好给它一个更独特的名称，可以像wskConnection 或wskTerminal 一样简单

当您下载MZ-tools 时，您可以“查看源代码”，它会向您显示任何不会在您的程序中调用或使用的过程和变量...这通常会给错误命名的变量或过程提供额外的提示

Answer 2

你的发送程序是错误的：

Private Sub cmdSend_Click()
  Dim strSData As String
  txtSend.Text = strSData
  Winsock.SendData strSData
End Sub

您在 txtSend 中显示 strSata ... 而 strSData 仍然是一个空字符串 .. 之后您通过 Winsock 控件发送空字符串

你可能是说：

Private Sub cmdSend_Click()
  Dim strSData As String
  strSData = txtSend.Text
  Winsock.SendData strSData
End Sub

它将 txtSend.Text 读入你的字符串变量，然后通过 Winsock 控件发送它

服务器可能想要在你的字符串末尾添加一些特殊字符，所以不要忘记添加它...通常你必须添加一个回车符：

strSData = strSData & vbCr