搜索具有重复元素的记录列表

Question

我需要在 Erlang 中制作一个通讯录。除了一个给我带来问题的功能之外，我几乎做了所有事情。

我的记录是：

-record(contact, {fname, lname, phone=[], mail=[], city=[], street=[]}).

我必须编写一个函数来搜索 contact 的实例并找到具有特定 city 名称的所有实例，并为这些实例返回 {fname,lname} 元组。不同的联系人当然可以拥有相同的城市。

当我需要 mail 和 phone 字段的类似功能时，我是这样做的：

findByPhone(_,[]) -> {error,"not found"};
findByPhone(Phone,[H|T]) ->
  case findPhoneForUser(Phone, H#contact.phone) of
    true -> {H#contact.fname, H#contact.lname};
    false -> findByPhone(Phone, T)
  end.
findPhoneForUser(_,[]) -> false;
findPhoneForUser(Phone, [Phone|_]) -> true;
findPhoneForUser(Phone, [_|T]) -> findPhoneForUser(Phone, T).

但是mail 和phone 都是唯一值，所以只要找到一个，函数就完成了。对于city，一次搜索可以产生多个返回值，因此它必须收集所有匹配项。

如何处理这个问题？我考虑过类似的列表推导：

{X,Y} || X<-H#contact.fname, Y<-H#contact.lname, City=:=H#contact.city

但它会从单个 ASCII 码返回元组：/

Answer 1

您可以使用列表推导。假设您的通讯录存储在名为AddressBook 的变量中，而您要匹配的城市存储在名为City 的变量中，则以下操作将起作用：

[{C#contact.fname, C#contact.lname} || C <- AddressBook, C#contact.city == City].

还请注意，您可以使用lists:keyfind/3 function 简化您的findByPhone 函数：

findByPhone(Phone, AddressBook) ->
    case lists:keyfind(Phone, #contact.phone, AddressBook) of
        #contact{fname=Fname, lname=Lname} -> {Fname, Lname};
        false -> {error, not_found}
    end.

这是可行的，因为记录实际上是元组。用作lists:keyfind/3 的第二个参数的构造#contact.phone 提供了基础元组的phone 字段的元素编号。事实上，您可以使用这种方法编写一个非导出的 find 函数来支持您记录中的任何唯一字段，然后为每个此类可搜索字段编写导出函数：

find(Value, Field, AddressBook) ->
    case lists:keyfind(Value, Field, AddressBook) of
        #contact{fname=Fname, lname=Lname} -> {Fname, Lname};
        false -> {error, not_found}
    end.

findByPhone(Phone, AddressBook) -> find(Phone, #contact.phone, AddressBook).
findByMail(Mail, AddressBook) -> find(Mail, #contact.mail, AddressBook).