将包含字符串类型成员的记录保存到文件（Delphi，Windows）

Question

我的记录类似于：

type
  TNote = record
    Title : string;
    Note  : string;
    Index : integer;
  end;

简单。我选择将变量设置为字符串（而不是字符数组）的原因是我不知道这些字符串将有多长。它们可以是 1 个字符长、200 或 2000 个字符。 当然，当我尝试将记录保存到类型文件（...的文件）时，编译器会抱怨我必须为字符串指定大小。 有没有办法克服这个问题？还是一种将这些记录保存到无类型文件并仍然保持可搜索方式的方法？

请不要向我指出可能的解决方案，如果您知道解决方案，请发布代码。 谢谢

Answer 1

你不能用键入的文件来做到这一点。使用 TFileStream 尝试类似的操作：

type
   TStreamEx = class helper for TStream
   public
      procedure writeString(const data: string);
      function readString: string;
      procedure writeInt(data: integer);
      function readInt: integer;
  end;

function TStreamEx.readString: string;
var
   len: integer;
   iString: UTF8String;
begin
   self.readBuffer(len, 4);
   if len > 0 then
   begin
      setLength(iString, len);
      self.ReadBuffer(iString[1], len);
      result := string(iString);
   end;
end;

procedure TStreamEx.writeString(const data: string);
var
   len: cardinal;
   oString: UTF8String;
begin
   oString := UTF8String(data);
   len := length(oString);
   self.WriteBuffer(len, 4);
   if len > 0 then
      self.WriteBuffer(oString[1], len);
end;

function TStreamEx.readInt: integer;
begin
   self.readBuffer(result, 4);
end;

procedure TStreamEx.writeInt(data: integer);
begin
   self.WriteBuffer(data, 4);
end;

type
  TNote = record
    Title : string;
    Note  : string;
    Index : integer;
    procedure Save(stream: TStream);
  end;

procedure TNote.Save(stream: TStream);
var
   temp: TMemoryStream;
begin
   temp := TMemoryStream.Create;
   try
      temp.writeString(Title);
      temp.writeString(Note);
      temp.writeInt(Index);
      temp.seek(0, soFromBeginning);
      stream.writeInt(temp.size);
      stream.copyFrom(temp, temp.size);
   finally
      temp.Free;
   end;
end;

我将把加载过程留给你。相同的基本思想，但它不需要临时流。通过每个条目前面的记录大小，您可以阅读它并知道如果您正在寻找某个记录而不是阅读整个内容，可以跳过多远。

编辑：这是专门为使用 Unicode 字符串的 Delphi 版本编写的。在旧版本上，您可以将其简化很多。

Answer 2

为什么不把它写成 XML 呢？请参阅我的会话“Practical XML with Delphi”了解如何开始。

另一种可能性是将您的记录放入从 TComponent 降级的类中，并在 DFM 文件中存储/检索您的数据。

This Stackoverflow entry 向您展示了如何做到这一点。

--杰罗恩

PS：抱歉，我的 XML 答案有点密集；我实际上正在参加两个会议（BASTA! 和DelphiLive! Germany）。

基本上你需要做的很简单：创建一个示例 XML 文件，然后启动 Delphi XML Data Binding Wizard（从版本 6 开始在 Delphi 中可用）。

该向导将为您生成一个单元，该单元具有将 XML 映射到 Delphi 对象的接口和类，以及一些用于从文件中读取它们、创建新对象等的辅助函数。我的会话（参见上面的第一个链接）实际上包含了这个过程的大部分细节。

以上链接是一个演示 Delphi XML 数据绑定向导用法的视频。

Answer 3

您可以使用两个不同的文件，一个仅以某种方便的方式存储字符串，另一个存储带有对字符串的引用的记录。这样，即使您不知道实际内容的大小，您仍然可以轻松访问记录文件。

（抱歉没有代码。）

Answer 4

  TNote = record
    Title : string;
    Note  : string;
    Index : integer;
  end;

可以翻译成

  TNote = record
    Title : string[255];
    Note  : string[255];
    Index : integer;
  end;

并使用 Stream.writebuffer(ANodeVariable, sizeof(TNode)，但您说在这种情况下字符串超过 255 个字符，如果字符串超过 65535 个字符，则将 WORD 更改为 INTEGER

type
TNodeHeader=Record
  TitleLen,
  NoteLen: Word;
end;

(* this is for writing a TNode *)
procedure saveNodetoStream(theNode: TNode; AStream: TStream);
var
  header: TNodeHeader;
  pStr: PChar;
begin
  ...
  (* writing to AStream which should be initialized before this *)
  Header.TitleLen := Length(theNode.Title);
  header.NodeLen := Length(theNode.Note);
  AStream.WriteBuffer(Header, sizeof(TNodeHeader);
  (* save strings *)
  PStr := PChar(theNode.Title);
  AStream.writeBuffer(PStr^, Header.TitleLen);
  PStr := PChar(theNode.Note);
  AStream.writebuffer(PStr^, Header.NoteLen);
  (* save index *)
  AStream.writebuffer(theNode.Index, sizeof(Integer));
end;
(* this is for reading a TNode *)
function readNode(AStream: TStream): TNode;
var
  header: THeader
  PStr: PChar;
begin
  AStream.ReadBuffer(Header, sizeof(TNodeHeader);
  SetLength(Result.Title, Header.TitleLen);
  PStr := PChar(Result.Title);
  AStream.ReadBuffer(PStr^, Header.TitleLen);
  SetLength(Result.Note, Header.NoteLen);
  PStr := PChar(Result.Note);
  AStream.ReadBuffer(PStr^, Header.NoteLen);
  AStream.ReadBuffer(REsult.Index, sizeof(Integer)(* 4 bytes *);
end;

Answer 5

您可以使用函数available in this Open Source unit。

它允许您将任何记录内容序列化为二进制，甚至包括其中的动态数组：

type
  TNote = record
    Title : string;
    Note  : string;
    Index : integer;
  end;

var
  aSave: TRawByteString;
  aNote, aNew: TNote;
begin
  // create some content
  aNote.Title := 'Title';
  aNote.Note := 'Note';
  aNote.Index := 10;
  // serialize the content
  aSave := RecordSave(aNote,TypeInfo(TNote));
  // unserialize the content
  RecordLoad(aNew,pointer(aSave),TypeInfo(TNote));
  // check the content
  assert(aNew.Title = 'Title');
  assert(aNew.Note = 'Note');
  assert(aNew.Index = 10);
end;