Haskell 是否提供了一种将函数映射到数据成员的方法？

Question

我是一名 Haskell 菜鸟，我经常发现自己必须使用模式匹配分解数据，才能将函数应用于其中一个成员，然后重新组装它。

说我有：

data Car = Car { gas :: Int, licensePlate :: String }

我希望它在行驶时将油量减半并加油，我正在这样做：

mapGas:: (Int -> Int) -> Car -> Car
mapGas f (Car aGas aLicensePlate) = Car (f aGas) aLicensePlate

drive:: Car -> Car
drive = mapGas (flip div 2)

refuel:: Int -> Car -> Car
refuel = mapGas . (+)

有没有办法做到这一点而不必定义辅助函数 mapGas？因为当数据由许多字段组成时，必须为数据的每个成员编写一个映射函数会变得相当麻烦。我知道可以为具有访问器的成员之一赋值：

runOutOfFuel:: Car -> Car
runOutOfFuel aCar = aCar { gas = 0 }

是否也可以使用访问器映射函数？如果有，怎么做？

Answer 1

只使用核心库？不，但是使用广泛使用的lens 包，是的。这是您的情况：

{-# LANGUAGE TemplateHaskell #-}

import Control.Lens.TH
import Control.Lens

data Car = Car { _gas :: Int, _licensePlate :: String }

makeLenses ''Car

现在，您可以轻松获取/设置/修改嵌套在数据结构中的字段。

runOutOfFuel:: Car -> Car
runOutOfFuel = gas .~ 0

drive:: Car -> Car
drive = gas %~ (`div` 2)

refuel:: Int -> Car -> Car
refuel c = gas +~ c

这里的神奇之处在于makeLenses ''Car 生成的gas 和licensePlate 函数与您的mapGas（实际上是mapGas = (gas %~)）相似（但更强大）。开始使用lens 非常令人生畏，但我建议您只阅读examples 部分。

Answer 2

没有语言特性可以做到这一点，但是，与 Haskell 中的许多东西一样，核心语言足够强大，可以以简单而优雅的方式实现。

您正在寻找的解决方案是一种称为镜头的值。镜头完全可以满足您的需求：它允许您获取任何类型的抽象数据并在其中的一部分上应用函数，从而获得包含修改部分的整个数据值。

我很喜欢here的镜头介绍。要使用包含的示例，您需要 lens 包。 (Or this one if you're using Stack)