【问题标题】:How to generically extract field names and values in Haskell records如何一般地提取 Haskell 记录中的字段名称和值
【发布时间】:2016-04-02 05:05:11
【问题描述】:

我最近了解到我可以在 Haskell 中执行以下操作:

{-# LANGUAGE DeriveDataTypeable #-}

import Data.Data

data MyRecord = MyRecord
  { field1 :: Int
  , field2 :: String
  , field3 :: String
  } deriving (Show,Eq,Data,Typeable)

main = print $ constrFields (toConstr (MyRecord 5 "Hello" "World"))

这会给我以下信息:

["field1","field2","field3"]

我怎样才能对记录中的值做同样的事情,像这样:

["5","Hello","World"]

我问是因为我使用Aeson 来获取这样的简单 JSON:

{
  "field1":5,
  "field2":"Hello",
  "field3":"World"
}

并像这样生成 Haskell 代码:

field1 :: Int
field1 = 5

field2 :: String
field2 = "Hello"

field3 :: String
field3 = "World"

我如何才能像解开记录的字段名称一样解开给定记录中的所有值?

【问题讨论】:

  • 您是否有不想将 JSON 直接解包到 MyRecord 中的原因?完成后,您可以通过在记录值上调用field1 等来获取值。
  • 我已经为 MyRecord 派生了 ToJSON 和 FromJSON,但我希望能够在不显式调用 field1、field2 等的情况下解开记录中的所有值,以便访问值。我想通常以字符串列表的形式获取所有值,就像我能够处理字段名称一样。
  • 作为这样一个函数的输出,您期望什么,您的示例已经表明列表不适用于您的字段具有不同的类型。 Map String 也是如此,您的字段类型也可能具有类似函数的不可显示类型,因此字符串表示通常是不可能的

标签: haskell generics record


【解决方案1】:

可以回答您的第一个问题。如果您乐于将数据类型的所有值转换为字符串,那么您确实可以使用通用编程库生成这样的列表,例如generics-sop:

{-# LANGUAGE DeriveGeneric, FlexibleContexts #-}

import qualified GHC.Generics as G
import Generics.SOP

data MyRecord = MyRecord
  { field1 :: Int
  , field2 :: String
  , field3 :: String
  } deriving (Show, Eq, G.Generic)

instance Generic MyRecord

stringValues ::
     (Generic a, All2 Show (Code a))
  => a -> [String]
stringValues a =
  hcollapse (hcmap (Proxy :: Proxy Show) (\ (I x) -> K (show x)) (from a))

test :: [String]
test = stringValues (MyRecord 5 "Hello" "world")

现在在 GHCi 中:

GHCi> test
["5","\"Hello\"","\"world\""]

但是,如果您的目标是保持原始类型,那么这会更加困难,因为结果类型必须是异构列表(实际上 generics-sop 在内部使用它,然后再将其转换回普通列表列表使用hcollapse)。

我并不完全清楚你真正想要实现什么。很有可能有更直接的解决方案。

【讨论】:

  • 很酷的例子! generics-sop 中的机制能否用于定义可扩展记录,例如 vinyl?
  • @danidiaz 原则上是的。至少从vinyl-0.5 开始,它们的Rec 类型在结构上与generics-sop 中的NP 同构。所以转换应该很容易,理论上两个库都可以合并。但到目前为止,做可扩展记录并不是generics-sop的主要关注点。
猜你喜欢
  • 2012-01-30
  • 1970-01-01
  • 1970-01-01
  • 2012-01-17
  • 1970-01-01
  • 2012-01-29
  • 1970-01-01
  • 1970-01-01
  • 2012-07-23
相关资源
最近更新 更多