getpeername() 总是失败，错误代码为 WSAENOTCONN

Question

我正在尝试使用getpeerinfo 来确保我可以在连接后获取对等信息。

它失败了：

WSAENOTCONN (10057)

套接字未连接。

由于未连接套接字并且（使用 sendto 在数据报套接字上发送时）未提供地址，因此不允许发送或接收数据的请求。

基本流程是：

• WSAStartup
• socket()
• connect()
• getpeerinfo()

我做错了什么？

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  Winapi.Winsock2;

procedure Main;
var
    hSocket: TSocket;
    wsData: TWSAData;
    nodeName: string;
    serviceName: string;
    localAddressLength: Cardinal;
    localAddress: TSockAddr;
    remoteAddressLength: Cardinal;
    remoteAddress: TSockAddr;
    name: TSockAddr;
    nameLen: Integer;
    errorCode: Integer;
    bRes: Boolean;
begin
    WSAStartup($0202, {var}wsData);

    hSocket := socket(AF_INET, SOCK_STREAM, 0);

    nodeName := 'stackoverflow.com';
    serviceName := '80';

    bRes := WSAConnectByNameW(hSocket, PChar(nodeName), PChar(serviceName),
            {var}localAddressLength, {var}localAddress,
            {var}remoteAddressLength, {var}remoteAddress,
            nil, nil);
    if not bRes then
    begin
        errorCode := WSAGetLastError;
        RaiseLastOSError(errorCode);
    end;

    //If no error occurs, getpeername returns zero.
    //Otherwise, a value of SOCKET_ERROR is returned,
    //and a specific error code can be retrieved by calling WSAGetLastError.
    nameLen := sizeof(name);
    errorCode := getpeername(hSocket, {var}name, {var}nameLen);
    if errorCode <> 0 then
    begin
        errorCode := WSAGetLastError;
        RaiseLastOSError(errorCode);
    end;
end;

begin
    try
        Main;
    except
        on E: Exception do
            Writeln(E.ClassName, ': ', E.Message);
    end;
end.

我们知道连接已连接，因为：

• 我们刚刚连接
• 我们做了thething 来检查套接字是否已连接

阅读奖励

• getpeername() always fails with error code WSAENOTCONN for a socket connected by using ConnectEx() function while the socket is connected

Answer 1

答案在 WinSock 文档中。

WSAConnectByNameW() function

当WSAConnectByName 函数返回TRUE 时，套接字s 处于连接套接字的默认状态。 在套接字上设置 SO_UPDATE_CONNECT_CONTEXT 之前，套接字s 不会启用先前设置的属性或选项。使用setsockopt 函数设置 SO_UPDATE_CONNECT_CONTEXT 选项。

所以，当WSAConnectByNameW() 返回 TRUE 时，getpeername() 失败并显示WSAENOTCONN，因为您没有调用setsockopt(SO_UPDATE_CONNECT_CONTEXT) 将套接字置于正确状态。 SOL_SOCKET Socket Options 文档对此进行了说明：

SO_UPDATE_CONNECT_CONTEXT

此选项与ConnectEx、WSAConnectByList、和WSAConnectByName函数一起使用。此选项在建立连接后更新套接字的属性。 如果要在连接的套接字上使用getpeername、getsockname、getsockopt、setsockopt 或shutdown 函数，则应设置此选项。

试试这个：

bRes := WSAConnectByNameW(hSocket, PChar(nodeName), PChar(serviceName),
  {var}localAddressLength, {var}localAddress,
  {var}remoteAddressLength, {var}remoteAddress,
  nil, nil);
if not bRes then
begin
  errorCode := WSAGetLastError;
  RaiseLastOSError(errorCode);
end;

// ADD THIS..
errorCode := setsockopt(hSocket, SOL_SOCKET, SO_UPDATE_CONNECT_CONTEXT, nil, 0);
if errorCode <> 0 then
begin
  errorCode := WSAGetLastError;
  RaiseLastOSError(errorCode);
end;

...

话虽如此，在您的示例中无需使用getpeername()，因为它返回的信息与WSAConnectByNameW() 已经在您传递给其RemoteAddress 参数的变量中返回的信息相同。