汇编：这个程序中 movl data_items(,%edi,4), %eax 的目的是什么

Question

此程序（来自 Jonathan Bartlett 的 Programming From the Ground Up）循环使用 .long 存储在内存中的所有数字，并将最大的数字放入 EBX 寄存器中，以便在程序完成时查看。

.section .data
data_items:
    .long 3, 67, 34, 222, 45, 75, 54, 34, 44, 33, 22, 11, 66, 0

.section .text
.globl _start

_start:
    movl $0, %edi
    movl data_items (,%edi,4), %eax
    movl %eax, %ebx
start_loop:
    cmpl $0, %eax
    je loop_exit
    incl %edi
    movl data_items (,%edi,4), %eax
    cmpl %ebx, %eax
    jle start_loop
    movl %eax, %ebx
    jmp start_loop
loop_exit:
    movl $1, %eax
    int $0x80

我不确定(,%edi,4) 在这个程序中的用途。我读过逗号用于分隔，而 4 用于提醒我们的计算机数据项中的每个数字都是 4 个字节长。既然我们已经用 .long 声明了每个数字是 4 个字节，为什么还要在这里再做一次呢？另外，有人可以更详细地解释这两个逗号在这种情况下的用途吗？

Answer 1

在 AT&T 语法中，内存操作数有 the following syntax¹:

displacement(base_register, index_register, scale_factor)

base、index、displacement组件可以任意组合使用，每个组件都可以省略

但显然，如果省略基址寄存器，则必须保留逗号，否则汇编程序将无法理解您遗漏了哪些组件。

所有这些数据都被结合起来计算您指定的地址，使用以下公式：

effective_address = displacement + base_register + index_register*scale_factor

（顺便说一句，这几乎正是您在 Intel 语法中指定的方式）。

因此，有了这些知识，我们就可以解码您的指令：

movl data_items (,%edi,4), %eax

匹配上面的语法，你会看到：

• data_items是位移；
• base_register被省略了，所以没有代入上式；
• %edi 是 index_register;
• 4 是 scale_factor。

因此，您是在告诉 CPU mov从位置 data_items+%edi*4 到寄存器 %eax 的 long。

*4 是必需的，因为数组的每个元素都是 4 字节宽，因此要将索引（%edi）转换为数组开头的偏移量（以字节为单位），您必须将其相乘4.

既然我们已经用 .long 声明了每个数字是 4 个字节，为什么还要在这里再做一次呢？

汇编器是对类型一无所知的低级工具。

• .long 不是一个数组声明，只是一个指令，让汇编器发出与其参数的 32 位表示对应的字节；
• data_items 不是一个数组，只是一个被解析到某个内存位置的符号，就像其他标签一样；事实上，您在它之后放置了一个 .long 指令，这对汇编程序没有特别的意义。

---

备注

1. 从技术上讲，还会有段说明符，但鉴于我们讨论的是 Linux 上的 32 位代码，我将完全省略段，因为它们只会增加混乱。