Perl -- 使用 JSON::RPC::Client 时出现“不是 HASH 引用”错误

Question

我是 Perl 的新手。 我有一个在 http://localhost:19000 运行的 JSON-RPC 服务器，我需要调用 checkEmail() 方法。

use JSON::RPC::Client;

my $client = new JSON::RPC::Client;
my $url    = 'http://localhost:19000';

my $callobj = { 
    method  => 'checkEmail',
    params  => [ 'rprikhodchenko@gmail.com' ],
};

my $res = $client->call($url, $callobj);

if($res) {
     if ($res->is_error) {
         print "Error : ", $res->error_message;
     }   
     else {
         print $res->result;
     }   
  }
  else {
     print $client->status_line;
  }

当我尝试启动它时，它会显示以下信息：

perl ./check_ac.pl
Not a HASH reference at /usr/local/share/perl/5.10.1/JSON/RPC/Client.pm line 193.

UPD：

完整的堆栈跟踪：

perl -MCarp::Always ./check_ac.pl
Not a HASH reference at /usr/local/share/perl/5.10.1/JSON/RPC/Client.pm line 193
        JSON::RPC::ReturnObject::new('JSON::RPC::ReturnObject', 'HTTP::Response=HASH(0x9938d48)', 'JSON=SCALAR(0x96f1518)') called at /usr/local/share/perl/5.10.1/JSON/RPC/Client.pm line 118
        JSON::RPC::Client::call('JSON::RPC::Client=HASH(0x944a818)', 'http://localhost:19000', 'HASH(0x96f1578)') called at ./check_ac.pl line 11

Answer 1

这个错误意味着你的 JSON-RPC 服务器实际上不是一个，因为它不满足requirement 7.3。当JSON::RPC::Client 假设 JSON-RPC 服务返回的文档是格式正确的（即 JSON 对象）时触发该错误，而这种假设结果是错误的。向JSON::RPC::Client 的作者报告错误将是请求更好的错误消息的适当方式。

我会通过找出导致JSON::RPC::Client 阻塞的服务器返回的内容来解决此类问题。不幸的是，JRC 未能提供足够的挂钩点来发现这一点，所以你必须有点棘手。

我不喜欢编辑外部库，因此我建议使用扩展和覆盖方法来检测 JSON-RPC 服务器的流量。像这样的东西（check_ac.pl）：

use Data::Dumper qw();

package JSON::RPC::InstrumentedClient;
use base 'JSON::RPC::Client';

# This would be better done with Module::Install, but I'm limiting dependencies today.
sub _get {
    my ($self, @args) = @_;

    return $self->_dump_response($self->SUPER::_get(@args));
}

sub _post {
    my ($self, @args) = @_;

    return $self->_dump_response($self->SUPER::_post(@args));
}

sub _dump_response {
    my ($self, $response) = @_;

    warn Data::Dumper::Dump([$response->decoded_content], [qw(content)]);
    return $response;
}

package main;

my $client = JSON::RPC::InstrumentedClient->new();
my $url    = 'http://localhost:19000';

... # rest of check_ac.pl

这包含了对JSON::RPC::Client 在内部进行的_get 和_post 的调用，以便您检查Web 服务器在响应我们发出的请求时实际所说的内容。上述代码转储页面的文本内容；在您的情况下，这可能不是正确的事情，如果遇到错误会爆炸。它只是一个调试辅助，帮助您从客户端代码端找出服务器出了什么问题。

我想，现在的警告已经足够了。祝你好运。

Answer 2

这似乎是method new of JSON::RPC::ReturnObject 中的一个错误。

sub new {
    my ($class, $obj, $json) = @_;
    my $content = ( $json || JSON->new->utf8 )->decode( $obj->content );

    #...
# line 193
    $content->{error} ? $self->is_success(0) : $self->is_success(1);
    #...
}

$content 的值将是从JSON::decode() 调用返回的值。但是查看文档，JSON->decode() 似乎返回了一个标量，它可以是一个数字、一个字符串、一个数组引用、或一个哈希引用。

不幸的是，JSON::RPC::ReturnObject->new() 在尝试将其作为 hashref 访问之前并没有检查 JSON->decode() 返回的类型。鉴于您的错误，我将继续并假设它在您的情况下得到的结果是不是之一。 :-)

我不知道是否有办法强制从您的代码中进行修复。我建议联系author 并让他知道这个问题，和/或filing a bug。