如何在 Perl 的 qx{} 语句中将变量的内容作为 STDIN 管道传输？

Question

我基本上想这样做：

$_ = "some content that need to be escaped &>|\"$\'`\s\\";
qx{echo $_ | foo}

这里有两个问题。首先$_ 的内容需要转义，因为它可以包含二进制数据。其次，调用echo 可能效率稍低。

如何将一些内容作为 STDIN 简单地通过管道传输到 Perl 中的命令？

Answer 1

以下假设 @cmd 包含程序及其参数（如果有）。

my @cmd = ('foo');

---

如果要捕获输出，可以使用以下任意一种：

use String::ShellQuote qw( shell_quote );
my $cmd1 = shell_quote('printf', '%s', $_);
my $cmd2 = shell_quote(@cmd);
my $output = qx{$cmd1 | $cmd2};

use IPC::Run3 qw( run3 );
run3(\@cmd, \$_, \my $output);

use IPC::Run qw( run );
run(\@cmd, \$_, \my $output);

---

如果您不想捕获输出，可以使用以下任何一种：

use String::ShellQuote qw( shell_quote );
my $cmd1 = shell_quote('printf', '%s', $_);
my $cmd2 = shell_quote(@cmd);
system("$cmd1 | $cmd2");

system('/bin/sh', '-c', 'printf "%s" "$0" | "$@"', $_, @cmd);

use String::ShellQuote qw( shell_quote );
my $cmd = shell_quote(@cmd);
open(my $pipe, '|-', $cmd);
print($pipe $_);
close($pipe);

open(my $pipe, '|-', '/bin/sh', '-c', '"$@"', 'dummy', @cmd);
print($pipe $_);
close($pipe);

use IPC::Run3 qw( run3 );
run3(\@cmd, \$_);

use IPC::Run qw( run );
run(\@cmd, \$_);

---

如果您不想捕获输出，但也不想看到它，您可以使用以下任何一种：

use String::ShellQuote qw( shell_quote );
my $cmd1 = shell_quote('printf', '%s', $_);
my $cmd2 = shell_quote(@cmd);
system("$cmd1 | $cmd2 >/dev/null");

system('/bin/sh', '-c', 'printf "%s" "$0" | "$@" >/dev/null', $_, @cmd);

use String::ShellQuote qw( shell_quote );
my $cmd = shell_quote(@cmd);
open(my $pipe, '|-', "$cmd >/dev/null");
print($pipe $_);
close($pipe);

open(my $pipe, '|-', '/bin/sh', '-c', '"$@" >/dev/null', 'dummy', @cmd);
print($pipe $_);
close($pipe);

use IPC::Run3 qw( run3 );
run3(\@cmd, \$_, \undef);

use IPC::Run qw( run );
run(\@cmd, \$_, \undef);

---

注意事项：

• 使用printf 的解决方案将对传递给程序的STDIN 的数据大小施加限制。

• 使用printf 的解决方案无法将 NUL 传递给程序的 STDIN。

• 使用 IPC::Run3 和 IPC::Run 的解决方案不涉及 shell。这样可以避免问题。

• 您可能应该使用来自 IPC::System::Simple 的 system 和 capture 而不是内置的 system 和 qx 来获得“免费”错误检查。

  李>

Answer 2

这个答案是一个非常幼稚的方法。它很容易陷入僵局。 不要使用它！

ikegami explains in a comment 下方：

如果父级向连接到子级 STDIN 的管道写入足够多的内容，并且如果子级在从其 STDIN 读取之前向连接到其 STDOUT 的管道输出足够多的内容，则会出现死锁。 （在某些系统上可能只有 4KB。）解决方案涉及使用选择、线程等。更好的解决方案是使用已经为您解决问题的工具（IPC::Run3 或 IPC::跑）。 IPC::Open2 和 IPC::Open3 级别太低，在大多数情况下都无法使用

我将保留原始答案，但鼓励读者从其他答案之一中选择解决方案。

---

您可以使用IPC::Open2 中的open2 来读取和写入同一个进程。

现在您无需担心逃避任何事情。

use IPC::Open2;
use FileHandle;

my $writer = FileHandle->new;
my $reader = FileHandle->new;

my $pid = open2( $reader, $writer, 'wc -c' );

# write to the pipe
print $writer 'some content that need to be escaped &>|\"$\'`\s\\';

# tell it you're done
$writer->close;

# read the out of the pipe
my $line = <$reader>;
print $line;

这将打印48。

请注意，您不能将双引号 "" 用于您显示的确切输入，因为反斜杠 \ 的数量是错误的。

请参阅perldoc open 和perlipc 了解更多信息。

Answer 3

我喜欢@simbabque 提供的解决方案，因为它避免了调用Shell。无论如何，为了比较，通过使用 Bash Here string，可以使用 Bash（但避免使用 echo）获得更短的解决方案：

$_ = q{some content that need to be escaped &>|\"$\'`\s\\};
$_ =~ s/'/'"'"'/g; # Bash needs single quotes to be escaped
system 'bash', '-c', "foo <<< '$_'";

而且，如果您需要捕获命令的输出：

use Capture::Tiny 'capture_stdout';
my $res = capture_stdout { system 'bash', '-c', "foo <<< '$_'" };