我可以访问从 Delphi CreateProcess 命令返回的字符串吗？答案

【问题标题】：Can I access the string returned from a Delphi CreateProcess command?我可以访问从 Delphi CreateProcess 命令返回的字符串吗？
【发布时间】：2008-12-05 10:51:19
【问题描述】：

我正在使用 Win32 CreateProcess 函数来执行对外部可执行文件的调用。可执行文件返回一个字符串。

有没有一种方法可以在调用可执行文件后捕获并查询返回的字符串？如果做不到这一点，我可能不得不将字符串写到可执行文件中的文件中，并在调用完成后在调用程序中读取它。不过，这似乎很蹩脚。

【问题讨论】：

标签： string delphi createprocess delphi-5

【解决方案1】：

Jedi Code Library 包含函数 CreateDOSProcessRedirected，它运行一个进程并为其提供输入和输出文件。您可以将所需的输入（如果有）放入输入文件，并从输出文件中读取过程输出（如果有）（在过程完成后）。

JCL 中就是这样实现的：

function CreateDOSProcessRedirected(const CommandLine, InputFile, OutputFile: string): Boolean;
var
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
  SecAtrrs: TSecurityAttributes;
  hInputFile, hOutputFile: THandle;
begin
  Result := False;
  hInputFile := CreateFile(PChar(InputFile), GENERIC_READ, FILE_SHARE_READ,
    CreateInheritable(SecAtrrs), OPEN_EXISTING, FILE_ATTRIBUTE_TEMPORARY, 0);
  if hInputFile <> INVALID_HANDLE_VALUE then
  begin
    hOutputFile := CreateFile(PChar(OutPutFile), GENERIC_READ or GENERIC_WRITE,
      FILE_SHARE_READ, CreateInheritable(SecAtrrs), CREATE_ALWAYS,
      FILE_ATTRIBUTE_TEMPORARY, 0);
    if hOutputFile <> INVALID_HANDLE_VALUE then
    begin
      FillChar(StartupInfo, SizeOf(StartupInfo), #0);
      StartupInfo.cb := SizeOf(StartupInfo);
      StartupInfo.dwFlags := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
      StartupInfo.wShowWindow := SW_HIDE;
      StartupInfo.hStdOutput := hOutputFile;
      StartupInfo.hStdInput := hInputFile;
      Result := CreateProcess(nil, PChar(CommandLine), nil, nil, True,
        CREATE_NEW_CONSOLE or NORMAL_PRIORITY_CLASS, nil, nil, StartupInfo,
        ProcessInfo);
      if Result then
      begin
        WaitForSingleObject(ProcessInfo.hProcess, INFINITE);
        CloseHandle(ProcessInfo.hProcess);
        CloseHandle(ProcessInfo.hThread);
      end;
      CloseHandle(hOutputFile);
    end;
    CloseHandle(hInputFile);
  end;
end;

【讨论】：

【解决方案2】：

假设您想捕获 exe 正在写入标准输出的内容，你可以从

开始

yourprog.exe > results.txt

这会将输出写入results.txt，然后您可以对其进行读取和评估。

或者，您可以尝试this thread 中解释的方法：为您生成的进程的输出创建一个管道并从中读取。第 7 篇文章有一个关于如何在 C++ 中使用相关 WinApi 函数的源示例，应该很容易翻译成 Delphi。

【讨论】：

【解决方案3】：

可执行文件如何返回字符串？我所知道的可执行文件最多只能返回一个数字，即退出代码。

【讨论】：

【解决方案4】：

您可以使用共享内存在两个应用程序之间进行通信。

您可以使用 Win32 CreateFileMapping 函数，也可以使用互斥锁来同步对内存映射文件的调用。

以下代码创建文件。

var
  fMapping : THandle;
  pMapData : Pointer;

fMapping := CreateFileMapping($FFFFFFFF, nil, PAGE_READWRITE,
             0, MAPFILESIZE, pchar('MAP NAME GOES HERE'));

PMapData := MapViewOfFile(fMapping, FILE_MAP_ALL_ACCESS, 0, 0, 0);

以下代码关闭地图文件

if PMapData <> nil then
  UnMapViewOfFile(PMapData);
if fMapping <> 0 then
  CloseHandle(fMapping);

【讨论】：