如何在 Loader 中中止加载组件？

Question

我有一个Loader 对象，它加载了一些非常重的组件。某些事件在加载过程中到达，需要停止加载并返回以清空Loader。有可能吗？

Answer 1

中止对象创建

如 Qt 所述，存在三种方法来卸载/中止对象实例化：

1. 将Loader.active 设置为false
2. 将Loader.source 设置为空字符串
3. 将Loader.sourceComponent 设置为undefined

异步行为

为了能够在加载期间更改这些属性，Loader.asynchronous 应该是 true，否则 GUI 线程正忙于加载对象。您还需要QQmlIncubationController 为您的QQmlEngine 控制用于对象孵化的空闲时间。没有这样的控制器Loader.asynchronous 没有任何效果。请注意，如果场景包含QQuickWindow，QQmlApplicationEngine 会自动安装默认控制器。

错误

直到最后测试的 Qt 版本（Qt 5.8.0、5.9.0 beta），在中止未完成的对象孵化时存在严重的内存泄漏（至少在某些情况下，包括 derM 答案中的示例）导致大型组件的内存使用量快速增加。将创建一个 bug report，其中包含建议的解决方案。

Answer 2

我不知道您的问题是什么，那些 在加载程序完成之前被销毁的对象，但问题可能存在吗？如果没有，这应该工作： 如果它没有帮助，请在您的问题中添加一些代码，以重现您的问题。

ma​​in.qml

import QtQuick 2.7
import QtQuick.Controls 2.0

ApplicationWindow {
    id: root
    visible: true
    width: 400; height: 450

    Button {
        text: (complexLoader.active ? 'Loading' : 'Unloading')
        onClicked: complexLoader.active = !complexLoader.active
    }

    Loader {
        id: complexLoader
        y: 50
        width: 400
        height: 400
        source: 'ComplexComponent.qml'
        asynchronous: true
        active: false
        // visible: status === 1
    }

    BusyIndicator {
        anchors.fill: complexLoader
        running: complexLoader.status === 2
        visible: running
    }
}

ComplexComponent.qml

import QtQuick 2.0

Rectangle {
    id: root
    width: 400
    height: 400
    Grid {
        id: grid
        anchors.fill: parent
        rows: 50
        columns: 50
        Repeater {
            model: parent.rows * parent.columns
            delegate: Rectangle {
                width: root.width / grid.columns
                height: root.height / grid.rows
                color: Qt.rgba(Math.random(index),
                               Math.random(index),
                               Math.random(index),
                               Math.random(index))
            }
        }
    }
}