德尔福 XE2 总成

Question

我有以下在 Delphi 2006 中工作的函数，但在 Delphi XE2 下它在处理 RET 时会给出访问冲突错误或特权指令错误。

function Q_TrimChar(const S: string; Ch: Char): string;
asm
        PUSH    ESI
        MOV     ESI,ECX
        TEST    EAX,EAX
        JE      @@qt
        MOV     ECX,[EAX-4]
        TEST    ECX,ECX
        JE      @@qt
        PUSH    EBX
        PUSH    EDI
        MOV     EBX,EAX
        MOV     EDI,EDX
        XOR     EDX,EDX
        MOV     EAX,ESI
        CALL    System.@LStrFromPCharLen
        MOV     EDX,EDI
        MOV     ECX,[EBX-4]
@@lp1:  CMP     DL,BYTE PTR [EBX]
        JNE     @@ex1
        INC     EBX
        DEC     ECX
        JNE     @@lp1
        MOV     EDX,[ESI]
        JMP     @@wq
@@ex1:  DEC     ECX
@@lp2:  CMP     DL,BYTE PTR [EBX+ECX]
        JNE     @@ex2
        DEC     ECX
        JMP     @@lp2
@@ex2:  MOV     EDI,[ESI]
        LEA     EDX,[EDI+ECX+1]
@@lp3:  MOV     AL,BYTE PTR [EBX+ECX]
        MOV     BYTE PTR [EDI+ECX],AL
        DEC     ECX
        JNS     @@lp3
@@wq:   MOV     EAX,[ESI]
        MOV     BYTE PTR [EDX],0
        SUB     EDX,EAX
        MOV     [EAX-4],EDX
        POP     EDI
        POP     EBX
        POP     ESI
        RET
@@qt:   MOV     EAX,ESI
        CALL    System.@LStrClr
        POP     ESI
end;

我不太了解组装。有什么问题？

Answer 1

我完全同意 David 的建议，即在 Pascal 中简单地编写代码并支持该答案。除非分析表明这是一个真正的瓶颈，否则就不需要 ASM。这里有两个版本。第一个更容易阅读，但第二个更高效：

function Q_TrimChar(const S: string; Ch: Char): string;
begin
  result := S;
  while (result <> '') and (result[1] = Ch) do Delete(Result, 1, 1);
  while (result <> '') and (result[Length(Result)] = Ch) do Delete(Result, Length(Result), 1);
end;

function Q_TrimChar(const S: string; Ch: Char): string;
var
  First, Last : integer;
begin
  First := 1;
  Last := Length(S);
  while (First < Last) and (S[First] = Ch) do inc(First);
  while (Last >= First) and (S[Last] = Ch) do Dec(Last);
  Result := copy(S, First, Last-First+1);
end;

Answer 2

Delphi 2006 使用单字节 ANSI 字符，因此 string 是 AnsiString，Char 是 AnsiChar。在 Delphi 2009 及更高版本上，使用两个字节的 Unicode 字符。这个函数不可能在两个编译器上都工作。

即使是使用 AnsiString 和 AnsiChar 的标准 hack 也不起作用。这个函数对 RTL 实现的假设很可能在现代 Delphi 中不再有效。

我会在 Pascal 中重新编写这个函数并让编译器完成这项工作。这不仅是解决您当前问题的最快方法，而且如果您选择解决这个问题，它还可以帮助您克服 64 位编译的障碍。