批处理文件以按名称整理文件

Question

我有以下文件夹：

Apple_folder
Pear_folder
Tomatoes_folder

在Apple_folder 内，我有以下文件：

Extracted-Apple_1.txt
Extracted-Apple_2.txt
Extracted-Pear_1.txt
Extracted-Pear_2.txt
Extracted-Apple_3.txt
Extracted-Tomatoes_1.txt

如何将Extracted-Pear_1.txt、Extracted-Pear_2.txt、Extracted-Tomatoes_1.txt 移动到它们的相关文件夹中，即在Apple_folder 下保留包含apple 的文件名等

预期的Apple_folder 内容：

Extracted-Apple_1.txt
Extracted-Apple_2.txt
Extracted-Apple_3.txt

我还是批处理脚本的初学者，所以不知道如何进行？

for %%a in (*.txt) do (
   echo %filename%    
   for /f "tokens=* delims=- _" %%f in (%filename%) do (
      if tokens==Pear move Extracted-Pear*.txt   "C:\Users\ABCD\Documents\Pear_folder\"
      if tokens==Tomatoes move Extracted-Pear*.txt "C:\Users\ABCD\Documents\Tomatoes_folder\"
   )

我正在使用此代码尝试重命名文件以避免覆盖目标文件夹中具有相似名称的文件。

setlocal enabledelayedexpansion
set /A counter=0

@echo off
for %%a in (*.txt) do (  
set /A counter+=1
    for /f "tokens=2 delims=-_" %%f in ("%%a") do (
        move Extracted-%%f_*.txt "C:\Users\ABCD\Documents\%%f_folder\Extracted-%%~nf_moved_!counter!.txt"
    )
)

只有一个文件被移动/重命名，然后得到一条错误消息

"Cannot move multiple files to a single file."

Answer 1

除了 Compo 提到的缺少的) 之外，还有对tokens 和delims 工作原理的误解。有关详细信息，请参阅SS64。

要使变量filename 工作，您需要delayed expansion，但您可以直接使用for 变量(%%a) 来工作：

@echo off
for %%a in (*.txt) do (
   for /f "tokens=2 delims=-_" %%f in ("%%a") do (
      ECHO move Extracted-%%f_*.txt  "C:\Users\ABCD\Documents\%%f_folder\"
   )
)

对tokens和delimiters部分的一些解释：

for /f 循环通过在“分隔符”处将字符串拆分为“令牌”：

tokens=* 告诉for 获取整个字符串，忽略分隔符（简化版本 - 实际上它有点复杂）。

Extracted-Apple_1.txt 由- 和_ 分隔，为您提供三个标记：Extracted、Apple 和.txt，第一个标记名为%%f（由您提供），下一个只是命名与以下字母。令牌 2 将是 %%g，令牌 3 将是 %%h。

现在变得有趣了：使用tokens=2，您告诉for 只获取第二个令牌（它将转到%%f（！），因为它是第一个（也是唯一一个）返回 令牌）

所以这就引出了上面的"tokens=2 delims=- _"。

注意我只是通过回显move 命令来禁用它（用于安全和故障排除）。只有当它按预期工作时，才删除ECHO 以启用move 命令。

编辑以符合“不覆盖”请求：

@echo off
setlocal enabledelayedexpansion
set "counter=0"
for /f "delims=" %%a in ('dir /b *.txt') do (
    for /f "tokens=2 delims=-_" %%f in ("%%a") do call :FileMove "%%a" "%%f"
)
pause
goto :eof

:FileMove
set counter=0
:FileNext
if exist "C:\Users\NABIL\Documents\TESTING\Batch_script\%~2_folder\%~n1_moved__%counter%.txt" (
  set /a counter+=1
  goto :fileNext
)
md "C:\Users\NABIL\Documents\TESTING\Batch_script\%~2_folder\" 2>nul
MOVE "%~1" "C:\Users\NABIL\Documents\TESTING\Batch_script\%~2_folder\%~n1_moved__%counter%.txt"
goto :eof

我将重命名和移动到子程序“外包”，主要是因为我们需要一个goto，这在代码块中是不可能的。我还将你的目标文件命名方案更改为我认为你想要的，但我可能错了 - 所以请检查一下。

Answer 2

setlocal enabledelayedexpansion
set /A counter=0

@echo off
for %%a in (*.txt) do (
    for /f "tokens=2 delims=-_" %%f in ("%%a") do (
set /A counter+=1 
MOVE "%%a" "C:\Users\ADMIN\Documents\TESTING\Batch_script\%%f_folder\Extracted-%%~nf_moved__!counter!.txt"
    )
)
pause