批处理命令从一个文件夹中删除除一个文件之外的所有内容（子文件夹和文件）

Question

首先，过去已经回答了类似的问题，但不完全是我的问题。在其他一些解决方案中，建议隐藏文件夹/文件和更改属性，我不希望这样做，除非没有更简单的方法可用。另外，我已经尝试过这里建议的解决方案（以及其他几个）：MS-DOS command to delete all files except one。

但由于两个原因无法满足我的需要：

1. 这也删除了文件，我不想。
2. 这并没有删除子文件夹，而只是删除了文件。

所以，我有文件夹 c:/users/data，在那里，我有 5 个文件夹和 6 个文件，我想删除除 web.config 之外的所有文件，为此我运行批处理文件，如下所示：

@echo off
for %%j in (C:\Users\data\*) do if not %%j == Web.config del %%j
pause

但是当我运行批处理文件时，这会删除所有文件，包括web.config，并且不会删除任何子文件夹，如果我使用/d 开关，它只会删除文件夹而不是文件。如何同时删除文件和文件夹？

Answer 1

我会这样做：

pushd "C:\Users\data" || exit /B 1
for /D %%D in ("*") do (
    rd /S /Q "%%~D"
)
for %%F in ("*") do (
    if /I not "%%~nxF"=="web.config" del "%%~F"
)
popd

基本代码取自我对问题Deleting Folder Contents but not the folder 的回答，但del 命令被第二个for 循环替换，该循环遍历所有文件并仅删除那些未命名为web.config 的文件。

请注意，这种方法不会触及原始父目录，也不会触及原始文件web.config。这一事实的最大优点是不会丢失任何属性（例如，创建日期和所有者）。

说明

• 通过pushd切换到根目录；如果失败，请跳过脚本的其余部分；
• 通过for /D 循环遍历根目录的所有直接子文件夹，并通过rd /S 递归删除它们及其所有内容；
• 通过标准for循环遍历位于根目录中的文件；使用循环变量的~nx修饰符扩展每个文件的基本名称（n）和扩展名（x），以不区分大小写的方式将其与给定文件名（if）进行比较（@ 987654336@) 并通过del 删除文件，仅在不匹配的情况下 (not);
• 最后通过popd恢复以前的工作目录；

---

您的代码中的主要问题是：

• 您将比纯文件名与预定义名称进行更多比较，因此不会找到任何匹配项。
• 您需要使用不区分大小写的比较，因为 Windows 不关心搜索文件名的大小写。
• 您没有在比较表达式周围加上引号，因此您可能会收到语法错误消息，具体取决于文件名中出现的特殊字符。
• 您正在使用del 命令仅删除文件；要删除目录，您还需要使用 rd。

Answer 2

我不确定 web.config 文件存储在哪里，或者是否有多个，所以...

只有一个web.config 文件

只需锁定文件（将文件重定向为输入）并删除其他任何内容

@echo off
    setlocal enableextensions disabledelayedexpansion

    pushd "c:\users\data" && >nul 2>nul (
        <"web.config" rmdir . /s /q
        popd
    )

代码将

1. (pushd) 切换到目标文件夹（我们需要确保这只会从预期位置删除信息）将其设置为当前活动目录并锁定它（我们无法删除当前活动目录）。如果命令可以更改到文件夹，那么

2. (rmdir) 将web.config 重定向为rmdir 命令的输入。这将锁定文件，因此在命令结束之前无法将其删除。 rmdir . /s /q 删除当前活动目录内（及以下）未锁定的任何内容

3. (popd) 取消pushd命令恢复之前的活动目录

多个文件夹中的多个 web.config 文件

按照@Dominique 指出的approach（复制、清理、恢复）

@echo off
    setlocal enableextensions disabledelayedexpansion

    pushd "c:\users\data" && >nul 2>nul (
        for %%t in ("%temp%\%~n0_%random%%random%%random%.tmp") do (
            robocopy . "%%~ft" web.config /s
            robocopy "%%~ft" . /mir
            rmdir "%%~ft" /s /q
        ) 
        popd
    )

代码将

1. (pushd) 更改为目标文件夹（我们需要确保这只会从预期位置删除信息）。如果命令可以更改到文件夹，那么

2. (for) 准备对要使用的临时文件夹的引用（随机名称）

3. (robocopy) 仅将web.config 文件（及其文件夹层次结构）从源文件夹复制到临时文件夹

4. (robocopy) 将临时文件夹镜像到源文件夹。这将删除临时副本中未包含的所有文件/文件夹

5. (rmdir) 删除临时文件夹

6. (popd) 取消pushd命令恢复之前的活动目录

一旦web.config 文件被保存，由于源中的文件将与 temporay 文件夹中的文件匹配，它们不会被第二个robocopy 调用复制回来，但源中的任何文件/文件夹不是临时文件夹中的存在将被删除以镜像临时文件夹中的结构。

Answer 3

我也设法做到了，与@aschipfl 非常相似

For /D %%k in (C:\Users\data) do (For /d %%m in ("%%k\*") do rmdir /s /q "%%m"
For %%m in ("%%k\*") do if not %%m == %%k\Web.config del /q "%%m")