【问题标题】:How to import Datadog JSON template in terraform DSL?如何在 terraform DSL 中导入 Datadog JSON 模板?
【发布时间】:2020-03-10 10:46:31
【问题描述】:
{
   "title":"xxxx",
   "description":"xxx",
   "widgets":[
      {
         "id":0,
         "definition":{
            "type":"timeseries",
            "requests":[
               {
                  "q":"xxxxxx{xxxx:xx}",
                  "display_type":"bars",
                  "style":{
                     "palette":"cool",
                     "line_type":"solid",
                     "line_width":"normal"
                  }
               }
           ]
        }
    ]
}

我有上面的 datadog json 模板,我必须将其导入 terraform 而不是将其重新创建为 terraform dsl。

【问题讨论】:

  • 您能否编辑您的问题以包含您迄今为止尝试过的任何 Terraform 代码?
  • @ydaetskcoR 这是实际转换后的版本github.com/prashanth-sams/…
  • 那我不确定我是否理解你的问题。您链接的版本有什么问题?
  • 我在 github 链接中的内容工作正常,但我的经理不想让它像模板版本一样;他说我使用的是资源而不是模块。他说应该像上课一样
  • 您也许可以使用JSON syntax 破坏某些东西,但它不会是一对一的导入,因此需要大量的争论才能使其正确。或者你可以从我猜的 JSON 生成 HCL。或者向 datadog 提供者提出拉取请求,让它有选择地接受仪表板的定义为 JSON blob,如 aws_cloudwatch_dashboard resource。

标签: terraform datadog


【解决方案1】:

我对这种 Datadog JSON 格式不是特别熟悉,但我在这里建议的一般模式有多个步骤:

  • 将序列化数据解码为正常的 Terraform 值。在这种情况下,将使用 jsondecode,因为数据是 JSON 序列化的。
  • 将原始数据转换和规范化为更方便在声明性 Terraform 配置中使用的一致形状。这通常会涉及至少一个named local value,其中包含一个使用for expressions 和the try function 的表达式以及类型转换函数,以尝试将原始数据强制转换为更一致的形状。
  • 将转换/归一化的结果与 Terraform 的资源和块重复构造(资源 for_each 和 dynamic 块)一起使用来描述数据如何映射到物理资源类型。

这是一个基本示例,用于展示一般原则。需要做更多的工作来捕捉您在初始示例中包含的所有细节。

variable "datadog_json" {
  type = string
}

locals {
  raw = jsondecode(var.datadog_json)
  screenboard = {
    title       = local.raw.title
    description = try(local.raw.description, tostring(null))
    widgets = [
      for w in local.raw.widgets : {
        type   = w.definition.type

        title       = w.definition.title
        title_size  = try(w.definition.title_size, 16)
        title_align = try(w.definition.title_align, "center")

        x      = try(w.definition.x, tonumber(null))
        y      = try(w.definition.y, tonumber(null))
        width  = try(w.definition.x, tonumber(null))
        height = try(w.definition.y, tonumber(null))

        requests = [
          for r in w.definition.requests : {
            q            = r.q
            display_type = r.display_type
            style        = tomap(try(r.style, {}))
          }
        ]
      }
    ]
  }
}

resource "datadog_screenboard" "acceptance_test" {
  title       = local.screenboard.title
  description = local.screenboard.description
  read_only   = true

  dynamic "widget" {
    for_each = local.screenboard.widgets
    content {
      type = widget.value.type

      title       = widget.value.title
      title_size  = widget.value.title_size
      title_align = widget.value.title_align

      x      = widget.value.x
      y      = widget.value.y
      width  = widget.value.width
      height = widget.value.height

      tile_def {
        viz = widget.value.type

        dynamic "request" {
          for_each = widget.value.requests
          content {
            q            = request.value.q
            display_type = request.value.display_type
            style        = request.value.style
          }
        }
      }
    }
  }
}

此处构建local.screenboard 的单独规范化步骤并不是绝对必要的:您可以将相同类型的规范化表达式(使用try 为未设置的事物设置默认值)直接放在@987654333 中@ 块参数,如果你想。我更喜欢将规范化视为一个单独的步骤,因为这样会在配置中为我们期望在 JSON 中找到的内容以及我们将为可选项目使用的默认值留下一个清晰的定义,而不是定义结果如何映射到物理 datadog_screenboard 资源。

我无法测试上面的示例,因为我没有 Datadog 帐户。如果其中有导致错误的小错别字/错误,我很抱歉。我希望展示从序列化数据文件映射到资源的一般原则,而不是提供现成的解决方案,所以我希望上面包含足够多的不同情况的示例,您可以看到如何扩展它您希望在此模块中支持的其余 Datadog JSON 功能。


如果此 JSON 格式是 Datadog 正式记录的交换格式,Terraform 的 Datadog 提供程序可以选择接受此格式的单个 JSON 字符串作为配置,以便于导出。这可能需要对 Datadog 提供程序本身进行更改,这超出了我可以在这里回答的范围,但可能值得在 GitHub 问题中提出,以便该提供程序简化此用例。

【讨论】:

  • 听起来很有趣;让我试一试
猜你喜欢
  • 2021-03-13
  • 1970-01-01
  • 2021-11-14
  • 2017-10-01
  • 2021-07-02
  • 2019-09-26
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
相关资源
最近更新 更多